I want to slide the blue point with Manipulate[]. However, the following code does not function:
Manipulate[
Plot[{0, 0}, {x, 500, 1000},
Prolog -> Inset[Graphics[{PointSize[Large], Blue, Point[{nonTime, 0}]}]]],
{nonTime, 500, 1000}]
But, below code does work:
plt = Plot[{0, 0}, {x, 500, 1000}];
Manipulate[
Show[{plt, Graphics[{PointSize[Large], Blue, Point[{nonTime, 0}]}]}],
{nonTime, 500, 1000}]
I wonder why the first piece code does not work.
Since you don't use the second argument of Inset to specify the position, the Graphics object is placed at the center of the enclosing graphic.
So you can use {nonTime, 0} as the second argument in Inset to have the point dynamically move with the slider:
Manipulate[Plot[{0, 0}, {x, 500, 1000},
Prolog -> Inset[Graphics[{PointSize[Large], Blue, Point[{0, 0}]}],
{nonTime, 0}]],
{nonTime, 500, 1000}]
If you don't have to use Inset a simpler alternative that gives the same result is to use
Prolog -> {PointSize[Large], Blue, Point[{nonTime, 0}]}
Without Prolog&Inset you can use Show:
Manipulate[
Show[{Plot[{0, 0}, {x, 500, 1000}],
Graphics[{PointSize[Large], Blue, Point[{nonTime, 0}]}]
}], {nonTime, 500, 1000}]
