adding error bar to histogram in gnuplot

Question

I have data file which looks like this

#col 1     2     3     4     5     6     7
#bench                 #these are max and min values 
#mark     #bar1 #bar2  #for the prevoius 2 values 
NOSHARE.2 43032 139412 100 45000 130000 140000
FALSE_SHARE.2 7035 24101 5000 7500 24100 25000
SHAREDVAR.2 11316 10248 10000 12000 10000 12000

I am able to generate a graph using gnuplot which looks like this enter image description here

I need to add max and min value as an error bar to each bar

Heres my gnuplot script

set output "truevsfalse.png"
set title " TRUE VS FALSE SHARING "
set boxwidth 0.9 absolute
set style fill   solid 1.00 border lt -1
set key inside right top vertical Right noreverse noenhanced autotitles nobox
set style histogram clustered gap 5 title  offset character 0, 0, 0
set datafile missing '-'
set style data histograms
set xtics border in scale 0,0 nomirror rotate by -45  offset character 0, 0, 0
set xtics  norangelimit
set ylabel "NUMBER      OF      SHARING"
set xlabel "BENCHMARK"
plot 'truevsfalse.dat'  using 2:xtic(1)  title "true(synced and nonsynced)sharing (both vcpus)" , '' u 3   title "false sharing (both vcpus)"

I tried this

plot 'truevsfalse.dat'  using($0- .05):2:4:5:xtic(1) with boxerrorbars  title "true(synced and nonsynced)sharing (both vcpus)" , '' using ($0+0.25):3:6:7 with boxerrorbars  title "false sharing (both vcpus)"

But failed , I either get just the error bars without histogram bars or if I try to modify a bit the image corrupts.
What am I doing wtong?

Thanks

I might have already answered a similar question. ( stackoverflow.com/questions/11718251/… ). Does that look the way you want it? — mgilson
– mgilson, Commented Aug 15, 2012 at 12:26

Sunhwan Jo · Accepted Answer · 2012-08-15 17:30:32Z

3

Basically, you need to overlay histogram and error bar plot, however, I see the problem is using xtic(1), which makes it difficult to overlay error bar plot on the box plot.

set xtics ('NOSHARE.2' 0, 'FALSE_SHARE.2' 1, 'SHAREDVAR.2' 2)
set bs 0.2 # width of a box
plot 'junk' u ($0-bs/2):2:(bs) w boxes title "true(synced and nonsynced)sharing (both vcpus)", \
     'junk' u ($0-bs/2):2:4:5 w yerror notitle, \
     'junk' u ($0+bs/2):3:(bs) w boxes title "false sharing (both vcpus)", \
     'junk' u ($0+bs/2):3:6:7 w yerror notitle

answered Aug 15, 2012 at 17:30

Sunhwan Jo

2,3111 gold badge15 silver badges13 bronze badges

Sign up to request clarification or add additional context in comments.

Collectives™ on Stack Overflow

adding error bar to histogram in gnuplot

1 Answer 1

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related