Parse XML file with windows batch

Question

How can I extract an STRING like "US_NY" between the tags <LOCATION></LOCATION> from a XML file? I tried it with FINDSTR, but the line breaks are problematic.

<?xml version="1.0" encoding="utf-16"?>
<DEVICE>
    <AGENT>
        <VERSION>
            2.0.0.2
        </VERSION>
        <CONNECTION>
            <LOCATION>
                US_NY
            </LOCATION>
            <SERVERIP>
                127.0.0.1
            </SERVERIP>
            <TCPPORT>
                5656
            </TCPPORT>
            <POLLINTERVAL>
                5
            </POLLINTERVAL>
        </CONNECTION>
    </AGENT>
</DEVICE>

I want to get the locations from somde devices. This information is stored in different XML files. Therefore I need to extract the STRING or line between the xml tag <location> and </location>. This should be done with windows batch script. — eichhorn
– eichhorn, Commented Nov 1, 2013 at 10:07
possible duplicate of A batch file to extract the value of a specific XML tag — jeb
– jeb, Commented Nov 1, 2013 at 10:19

Navin Rawat · Accepted Answer · 2013-11-01 10:31:23Z

15

You should use XML.EXE within batch to read an XML file. For more details go to http://xmlstar.sourceforge.net/

Batch File:

@echo off
for /f %%i in ('XML.EXE sel -t -v "//LOCATION" CP.xml') do set var=%%i
echo LOCATION is %var%

output:

LOCATION is US_NY

answered Nov 1, 2013 at 10:31

Navin Rawat

3,1381 gold badge22 silver badges32 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

MC ND · Accepted Answer · 2013-11-01 10:40:25Z

9

One more

@echo off
    setlocal enableextensions enabledelayedexpansion
    set "xmlFile=%~1"
    for /f "tokens=1,2 delims=:" %%n in ('findstr /n /i /c:"<LOCATION>" "%xmlFile%"') do (
        for /f "tokens=*" %%l in ('type "%xmlFile%" ^| more +%%n') do set "location=%%l" & goto endLoop
    )
:endLoop
    echo %location%

answered Nov 1, 2013 at 10:40

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

3 Comments

MC ND Over a year ago

@lucy, Look at the third line. xmlFile is assigned the file name passed as argument to the batch file. So, yes, it is the name of the file.

Zahra Over a year ago

using findstr has a major problem because it makes the command rely on xml file formatting. If you put multiple tags on the same line it fails to match the pattern!!

MC ND Over a year ago

@Greenish, i agree, xml handling from batch scripts should be done with something like xmlstartlet, but a) it is a non native solution (a problem for some environments) b) the problem in the OP question is the line breaks.

npocmaka · Accepted Answer · 2018-06-26 11:24:05Z

Here's the xpath.bat -small script that will allow you to get an xml node/attribute value by xpath expression without using external binaries.

For your case it can be used like this:

call xpath.bat  "location.xml" "//LOCATION"

or to assign the value to a variable:

for /f "tokens=* delims=" %%a  in  ('xpath.bat  "location.xml" "//LOCATION"') do (
   set "location=%%a"
)

Pure batch solution

 @echo off
        for /f "tokens=1 delims=:" %%L in ('findstr /n "<LOCATION>" some.xml') do ( 
         set begin_line=%%L
        )

        for /f "tokens=1 delims=:" %%L in ('findstr /n "</LOCATION>" some.xml') do ( 
         set /a end_line=%%L+1
        )

        echo showing lines between %end_line% and %begin_line%
        break>"%temp%\empty"
        for /f "delims=" %%l in ('fc "%temp%\empty" "some.xml" /lb  %end_line% /t ^|more +4 ^| findstr /B /E /V "*****" ^| more +%begin_line%') do (
         set "location=%%l"
         goto :break_for
        )
        :break_for
        echo %location%
        del /Q /F "%temp%\empty"

Replace some.xml with the name of your xml.

foxidrive · Accepted Answer · 2013-11-01 10:55:05Z

5

If you want to use a helper batch file (by aacini) then this will work:

@echo off
for /f "tokens=*" %%a in ('findrepl /i "<location>" /e:"</location>" /o:+1:-1 ^< "file.xml" ') do echo "%%a"

This uses a helper batch file called findrepl.bat from - https://www.dropbox.com/s/rfdldmcb6vwi9xc/findrepl.bat

Place findrepl.bat in the same folder as the batch file.

answered Nov 1, 2013 at 10:55

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

2 Comments

Jay Over a year ago

Clever dual-usage script, both CMD and JScript using built-in CScript. It even re-use itself to type the help if need be.

lww Over a year ago

findrepl.bat is no longer available for future generations.

Magoo · Accepted Answer · 2013-11-01 12:19:51Z

3

Pure batch -

@ECHO OFF
SETLOCAL
SET "location="&SET "grab="
FOR /f "tokens=*" %%a IN (q19722041.xml) DO (
 IF DEFINED grab SET location=%%a&SET "grab="
  IF /i "%%a"=="<LOCATION>" SET grab=Y
)
ECHO found location=%location%
GOTO :EOF

where q19722041.xml is your source .xml file.

answered Nov 1, 2013 at 12:19

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Comments

Community · Accepted Answer · 2017-05-23 11:53:26Z

1

Try this:

@echo off
setlocal EnableDelayedExpansion
set lastLine=0
< input.xml (for /F "delims=:" %%a in (
              'findstr /N /C:"<LOCATION>" input.xml') do (
   set /A skip=%%a-lastLine+1, lastLine=%%a+2
   for /L %%i in (1,1,!skip!) do set /P line=
   set /P "line=!line!" & echo:
))

Note: the answer is an adaptation of the answer (probably given by @Aacini) on this forum post: Windows batch FindStr to search for a string and matching line.

edited May 23, 2017 at 11:53

CommunityBot

11 silver badge

answered Nov 1, 2013 at 10:25

Alex Filipovici

32.8k7 gold badges60 silver badges81 bronze badges

Comments

Endoro · Accepted Answer · 2013-11-01 14:10:17Z

0

sed for Windows

sed -n "/<LOCATION>/{n;p}" file.xml

in a batch file:

for /f %%a in ('sed -n "/<LOCATION>/{n;p}" file.xml') do set "location=%%a"
echo(%location%

edited Nov 1, 2013 at 14:10

answered Nov 1, 2013 at 14:00

Endoro

37.7k8 gold badges54 silver badges64 bronze badges

Collectives™ on Stack Overflow

Parse XML file with windows batch

7 Answers 7

Comments

3 Comments

Comments

2 Comments

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

7 Answers 7

Comments

3 Comments

Comments

2 Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related