How to replace hostname with IP address in a network drive path using batch command

Question

set SourceDir=\\my_server\path    

if "%SourceDir:~0,2%"=="\\" (
  set sourceHost= REM not sure what to do. here I need to isolate hostname
  for /f "tokens=2" %%b in ('nslookup %SourceDir%^|find /i "Address"') do set ser_ip=%%b
  REM here I need to replace my_server with %ser_ip%     
)

In this code I'm trying to replace the host-name with IP address in a network path.

in the set sourceHost= REM not sure what to do. here I need to isolate hostname Line I need to isolate the hostname from the path
in the REM here I need to replace my_server with %ser_ip% line need to replace host name with retrieved ip address

if the nslookup ip adress is 10.12.13.14 last result should be \\10.12.13.14\path Please help me for these two lines. Thank you!

Are you getting the hostname of the pc it's running on, or the hostname of the server? Do you know the name of the server already? — Bali C
– Bali C, Commented Apr 6, 2017 at 14:57
its host name of the server. Network path pass to the batch file. So I have the hostname as the first part of the path. \\`my_server`\path — Nayana Adassuriya
– Nayana Adassuriya, Commented Apr 6, 2017 at 23:41

user6811411 · Accepted Answer · 2017-04-06 15:06:44Z

1

I'd go with ping instead of nslookup. If there are IPv6 addresses they are more difficult to parse and ping has a -4 option.
The ip is easy to extract as it is enclosed in square brackets.:

@Echo off&SetLocal EnableExtensions EnableDelayedExpansion
set "SourceDir=\\my_server\path"
if "%SourceDir:~0,2%"=="\\" (
  for /f "delims=\" %%H in ( "%SourceDir%"
  ) Do for /f "tokens=2delims=[]" %%b in ('ping -n 1 -4 %%H^|find "["'
  ) do Set "SourceDir=!SourceDir:%%H=%%b!"
)
Echo %SourceDir%

answered Apr 6, 2017 at 15:06

user6811411

Sign up to request clarification or add additional context in comments.

1 Comment

Nayana Adassuriya Over a year ago

I choose this answer because of the IPV6 thing @LotPings talks about, though aschipfi answer cater for my requirement.

aschipfl · Accepted Answer · 2017-04-06 18:19:43Z

1

What about this (assuming you want to stick to nslookup):

set "SourceDir=\\my_server\path"

if "%SourceDir:~0,2%"=="\\" (
  rem // Extract server name and splif off remaining path:
  for /F "tokens=1* delims=\" %%a in ("%SourceDir%") do set "sourceHost=%%a" & set "sourceShare=%%b"
  for /F "tokens=2" %%b in ('nslookup %SourceDir%^|find /I "Address"') do set "ser_ip=%%b"
  rem // Assemble new path by IP and former remaining path:
  echo "\\%ser_ip%\%sourceShare%"
)

answered Apr 6, 2017 at 18:19

aschipfl

35.3k12 gold badges62 silver badges106 bronze badges

Collectives™ on Stack Overflow

How to replace hostname with IP address in a network drive path using batch command

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related