How to use attribute values from another XML file as an element value selection in the current XML

Question

I have two XML files. One is the main XML file and the other one is used as a lookup table. Here is the main XML:

<Report>
      <row>
            <field1>test1</field1>
            <field2>test2</field2>
            <field3>test3</field3>
      </row>
      <row>
            <field1>test4</field1>
            <field2>test5</field2>
            <field3>test6</field3>
      </row>
</Report>

The lookup xml file looks like this:

<lookup>
      <fieldmapping name="field1">fieldA</fieldmapping>
      <fieldmapping name="field2">fieldB</fieldmapping>
      <fieldmapping name="field3">fieldC</fieldmapping>
</lookup>

Here is the output xml I want:

<Items>
      <Item>
           <FieldName name="fieldA">test1</FieldName>
           <FieldName name="fieldB">test2</FieldName>
           <FieldName name="fieldC">test3</FieldName>
      </Item>
      <Item>
           <FieldName name="fieldA">test4</FieldName>
           <FieldName name="fieldB">test5</FieldName>
           <FieldName name="fieldC">test6</FieldName>
      </Item>
</Items>

I am using the following XSLT and can not figure out how to select the value from field1, field2, and field3:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:variable name="mappingLookupDoc" select="document('lookup.xml')/lookup/fieldmapping "/>

<xsl:key name="mappingKey" match="fieldmapping " use="@name"/>

<xsl:template match="report">
    <xsl:apply-templates select="$mappingLookupDoc"/>
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="/">
    <Items xmlns="http://www.w3.org/1999/xhtml" schemaVersion="1.0">
        <xsl:for-each select="report/row">
            <Item>
                <xsl:for-each select="$mappingLookupDoc">
                    <xsl:variable name="fieldname" select="@name"/>
                    <FieldName>
                    <xsl:attribute name="name">
                            <xsl:value-of select="." />
                    </xsl:attribute>
                    <xsl:value-of select="/report/row/?????"/>
                    </FieldName>
                </xsl:for-each>
            </Item>
        </xsl:for-each>
    </Items>
</xsl:template>

If you were doing thid with an XSLT 1.0 processor, the problem would be in the scope for fieldname variable: it should be declared before you change the context with xsl:for-each instruction. — user357812
– user357812, Commented Feb 14, 2011 at 19:36

Martin Honnen · Accepted Answer · 2011-02-15 18:22:19Z

3

I would do it like this (assuming XSLT 2.0):

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
  version="2.0">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:key name="k1" match="fieldmapping" use="@name"/>

  <xsl:variable name="lookupDoc" select="doc('lookup.xml')"/>

  <xsl:template match="Report">
    <Items>
      <xsl:apply-templates/>
    </Items>
  </xsl:template>

  <xsl:template match="row">
    <Item>
      <xsl:apply-templates/>
    </Item>
  </xsl:template>

  <xsl:template match="row/*">
    <fieldName name="{key('k1', local-name(), $lookupDoc)}">
      <xsl:value-of select="."/>
    </fieldName>
  </xsl:template>

</xsl:stylesheet>

[edit] Here is an XSLT 1.0 rewrite of the above XSLT 2.0 stylesheet:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:key name="k1" match="fieldmapping" use="@name"/>

  <xsl:variable name="lookupDoc" select="document('lookup.xml')"/>

  <xsl:template match="Report">
    <Items>
      <xsl:apply-templates/>
    </Items>
  </xsl:template>

  <xsl:template match="row">
    <Item>
      <xsl:apply-templates/>
    </Item>
  </xsl:template>

  <xsl:template match="row/*">
    <xsl:variable name="this" select="."/>
    <xsl:variable name="lookup">
      <xsl:for-each select="$lookupDoc">
        <xsl:value-of select="key('k1', local-name($this))"/>
      </xsl:for-each>
    </xsl:variable>
    <fieldName name="{$lookup}">
      <xsl:value-of select="."/>
    </fieldName>
  </xsl:template>

</xsl:stylesheet>

edited Feb 15, 2011 at 18:22

answered Feb 14, 2011 at 17:29

Martin Honnen

169k6 gold badges100 silver badges122 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Fan Over a year ago

I am using XSLT 1.0 processor, so this is not working. But it does give me some idea how to do it. Thanks!

Fan Over a year ago

This one works great as well. Very neat. It is especially interesting that the variable definition contains a for-each statement. Thanks a lot!

Daniel Haley · Accepted Answer · 2011-02-15 18:20:34Z

1

This is the way I would do it (although I like Martin's use of xsl:key):

I modified main.xml and lookup.xml to show the dynamic name lookup.

main.xml

<?xml version="1.0" encoding="UTF-8"?>
<Report>
  <row>
    <field1>test1</field1>
    <field2>test2</field2>
    <field3>test3</field3>
    <newfield>testing new element</newfield>
  </row>
  <row>
    <field1>test4</field1>
    <field2>test5</field2>
    <field3>test6</field3>
    <newfield>testing new element again</newfield>
  </row>
</Report>

lookup.xml

<?xml version="1.0" encoding="UTF-8"?>
<lookup>
  <fieldmapping name="field1">fieldA</fieldmapping>
  <fieldmapping name="field2">fieldB</fieldmapping>
  <fieldmapping name="field3">fieldC</fieldmapping>
  <fieldmapping name="newfield">fieldD</fieldmapping>
</lookup>

XSLT 1.0 stylesheet

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes" method="xml"/>

  <xsl:variable name="mappingLookupDoc" select="document('lookup.xml')"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Report">
    <Items>
      <xsl:apply-templates/>
    </Items>
  </xsl:template>

  <xsl:template match="row">
    <Item>
      <xsl:apply-templates/>
    </Item>    
  </xsl:template>

  <xsl:template match="*[name() = $mappingLookupDoc/lookup/fieldmapping/@name]">
    <xsl:variable name="elemName" select="name()"/>
    <FieldName name="{$mappingLookupDoc/lookup/fieldmapping[@name=$elemName]}">
      <xsl:apply-templates/>
    </FieldName>
  </xsl:template>

</xsl:stylesheet>

output

<?xml version="1.0" encoding="UTF-8"?>
<Items>
  <Item>
      <FieldName name="fieldA">test1</FieldName>
      <FieldName name="fieldB">test2</FieldName>
      <FieldName name="fieldC">test3</FieldName>
      <FieldName name="fieldD">testing new element</FieldName>
  </Item>
  <Item>
      <FieldName name="fieldA">test4</FieldName>
      <FieldName name="fieldB">test5</FieldName>
      <FieldName name="fieldC">test6</FieldName>
      <FieldName name="fieldD">testing new element again</FieldName>
  </Item>
</Items>

edited Feb 15, 2011 at 18:20

answered Feb 14, 2011 at 17:39

Daniel Haley

53.1k7 gold badges75 silver badges97 bronze badges

5 Comments

Fan Over a year ago

This way works fine for XSLT 1.0 processor. The only thing I don't like is match="field1|field2|field3", if this could be dynamically from lookup file, then it will be great.

Daniel Haley Over a year ago

@Fan - I updated my answer with a different match. Maybe this will be dynamic enough without causing issues?

Daniel Haley Over a year ago

@Fan - Totally dynamic now. :-)

Fan Over a year ago

Yes. It works great! I have better understanding of XSLT now after looking at your change. Thanks a lot for the help.

Daniel Haley Over a year ago

@Fan - You are very welcome. Please consider accepting either my answer or Martin's answer by clicking on the checkmark next to the answer. :-)

Slava · Accepted Answer · 2011-03-16 12:55:45Z

Maybe something like this would be simpler:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

    <xsl:variable name="lookup" select="document('lookup.xml')/lookup/fieldmapping" />

    <xsl:template match="/">
        <Items>
            <xsl:apply-templates/>
        </Items>
    </xsl:template>

    <xsl:template match="row">
        <Item>
            <xsl:for-each select="./*">
                <xsl:variable name="this" select="local-name()"/>
                <xsl:variable name="name" select="$lookup[@name=$this]"/>
                <FieldName name="{$name}">
                    <xsl:copy-of select="./node()" />
                </FieldName>
            </xsl:for-each>
        </Item>
    </xsl:template>

</xsl:stylesheet>

Collectives™ on Stack Overflow

How to use attribute values from another XML file as an element value selection in the current XML

3 Answers 3

2 Comments

5 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

5 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related