batch script error level output is not showing expected output

I'm not sure exactly how you're trying to implement this, but it seems to me as if one of the following methods using the choice command utility should work for you.

Opening a cmd window for it to run inside:

%SystemRoot%\System32\cmd.exe /D/Q/C "%SystemRoot%\System32\choice.exe&If ErrorLevel 2 (Exit 5)Else Exit 0"

Running it in the same cmd window:

@%SystemRoot%\System32\choice.exe&If ErrorLevel 2 (Exit /B 5) Else Exit /B 0

You do not need to start a new cmd instance. As the code is right now, you also do not even require delayedexpansion

@echo off
set /P id="Enter yes or no: "
echo %id%
if /i "%id%" == "yes" (
     exit /b 0
   ) else (
     exit /b 5
)

Should you however require using delayedexpansion then use it with setlocal and do not start cmd with /V:on The code will be something like:

@echo off
setlocal enabledelayedexpansion
set /P id="Enter yes or no: "
echo !id!
if /i "!id!" == "yes" (
     exit /b 0
   ) else (
     exit /b 5
)

Note, the second example above is an example, it will work, but delayedexpansion is not required here at all.

Should you want to use conditional operators, which acts similarly to if and else then you can simply run:

@echo off
set /P id="Enter yes or no: "
echo %id% | findstr /i "yes">nul && exit /b 0 || exit /b 5

I do not really understand why you are using the start command to run a cmd.exe instance to run further commands – perhaps start could simply be omitted.

Anyway, if you do want to use start you need to be aware that it actually only starts the given command line but it does not wait until the executed command line is finished, unless you specify the /WAIT option. Not waiting implies that the final ErrorLevel state cannot yet be available.

Hence the command line should probably look like this:

start "" /WAIT cmd /V:ON /K "set /P id="Enter yes or no: " & echo(!id!& if /I "!id!"=="yes" (exit 0) else (exit 5)"`

You might have noticed that I changed a few more things:

• besides adding /WAIT, I also added an empty string "" as the first parameter of the start command to specify a window title; this is necessary to safely handle command lines that could contain quotation marks (otherwise the first quoted part might erroneously be interpreted as the window title);
• && lets the following command only be executed when the preceding one succeeds (hence it returns an exit code of zero), but I think you want to execute the following ones unconditionally, so I replaced && by & for that purpose;
• echo !id! returns ECHO is ON. or ECHO is OFF. when !id! expands to an empty string, so I used echo(!id! instead; then I removed the SPACE in front of the following &, which would be output too, unintentionally;
• an empty value of !id! would cause your if command line to result in a syntax error, so I introduced proper quotation; moreover, I specified a case-insensitive comparison by adding /I;
• finally, I replaced exit /B by exit, because the former is only needed in batch files to quit them without affecting the hosting cmd.exe instance, but for just quitting cmd.exe the latter is enough;