XSL output everythin including node name, attributes, text

Question

On XSLT, Is there a simple way to output everything of a variable?

My variable is something like:

<node a="a">
  a
  <node>
    b
  </node>
</node>

So i want to output it as it is including tag names, attributes, text etc.

Thanks!

AND:

is it possible not to output some tags? such as

<a>aa
<b>bb
<c>cc</c></b></a>

i want to avoid b tag from output but want to output c? thanks!

What do you mean by "output"? You mean "include in the result document"? — Francis Avila
– Francis Avila, Commented Dec 10, 2011 at 22:23
yes, sorry i am not used to functional programming may use wrong words :) — Ataman
– Ataman, Commented Dec 10, 2011 at 23:17

Francis Avila · Accepted Answer · 2011-12-10 22:23:45Z

3

<xsl:copy-of select="$variable"/>

answered Dec 10, 2011 at 22:23

Francis Avila

31.8k7 gold badges63 silver badges99 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Ataman Over a year ago

is it possible not to output some tags? such as <a>aa<b>bb<c>cc</c></b></a>. i want to avoid b tag form output but want to output c? thanks!

Dimitre Novatchev Over a year ago

@user446141: See in my answer solutions to both of your questions. :)

Dimitre Novatchev · Accepted Answer · 2011-12-10 23:29:13Z

Good question, +1.

This transformation provides the answers to both your questions:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vVarNode" select="/*/node"/>

 <xsl:variable name="vVarA" select="/*/a"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:copy-of select="$vVarNode"/>
  ===========

  <xsl:apply-templates select="$vVarA"/>
 </xsl:template>

 <xsl:template match="b">
  <xsl:apply-templates select="*"/>
 </xsl:template>
</xsl:stylesheet>

when applied on this XML document (from which the two variables are "loaded"):

<doc>
 <node a="a">
    a
    <node>
     b
    </node>
 </node>

 <a>aa
  <b>bb
    <c>cc</c>
  </b>
 </a>
</doc>

the wanted, correct result is produced (The content of the first variable is output "as-is", while b and its text-node children are "deleted" from what is output out of the content of the second variable):

<node a="a">
    a
    <node>
     b
    </node>
</node>
  ===========

  <a>aa
  <c>cc</c>
</a>

Collectives™ on Stack Overflow

XSL output everythin including node name, attributes, text

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related