Perl: Searching for item in an Array

Question

Given an array @A we want to check if the element $B is in it. One way is to say this:

Foreach $element (@A){
    if($element eq $B){
        print "$B is in array A";
    }
}

However when it gets to Perl, I am thinking always about the most elegant way. And this is what I am thinking: Is there a way to find out if array A contains B if we convert A to a variable string and use

index(@A,$B)=>0

Is that possible?

Related: stackoverflow.com/questions/7898499/… stackoverflow.com/questions/3086874/… — daxim
– daxim, Commented Apr 20, 2012 at 7:06

bvr · Accepted Answer · 2012-04-20 07:41:20Z

13

There are many ways to find out whether the element is present in the array or not:

Using foreach

foreach my $element (@a) {
    if($element eq $b) {
       # do something             
       last;
    }
}

Using Grep:
```
my $found = grep { $_ eq $b } @a;
```

Using List::Util module

use List::Util qw(first); 

my $found = first { $_ eq $b } @a;

Using Hash initialised by a Slice

my %check;
@check{@a} = ();

my $found = exists $check{$b};

Using Hash initialised by map

my %check = map { $_ => 1 } @a;

my $found = $check{$b};

edited Apr 20, 2012 at 7:41

bvr

9,69725 silver badges28 bronze badges

answered Apr 20, 2012 at 5:49

Nikhil Jain

8,3782 gold badges28 silver badges50 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

pilcrow Over a year ago

The List::Util::first() example is (potentially) subtly incorrect when searching for false values, since $found will also evaluate false. (die unless $found ... oops!) List::MoreUtils::any does the right thing here.

yazu · Accepted Answer · 2012-04-20 04:56:23Z

6

use 5.10.1;

$B ~~ @A and say '$B in @A';

answered Apr 20, 2012 at 4:56

yazu

4,7301 gold badge22 silver badges14 bronze badges

1 Comment

brian d foy Over a year ago

You have to be very careful with this because this distributes the match over the elements. If @A has an array reference element that contains $B, this will still match even though $B isn't a top level element of @A. The smart match is fundamentally broken for this and many other reasons.

obmib · Accepted Answer · 2012-04-20 05:51:14Z

0

use List::AllUtils qw/ any /;
print "\@A contains $B" if any { $B eq $_ } @A;

answered Apr 20, 2012 at 5:51

obmib

4762 silver badges7 bronze badges

3 Comments

bvr Over a year ago

I would recommend first in this case, as it does not have to traverse whole array. It can stop when item is found.

brian d foy Over a year ago

any can stop too because it needs only one element to be true.

pilcrow Over a year ago

Beware that first can also return a false value if it finds, e.g., "0", which would confound the example given in this answer. any has the desired semantics.

Collectives™ on Stack Overflow

Perl: Searching for item in an Array

3 Answers 3

1 Comment

1 Comment

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

1 Comment

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related