Batch Files, For Loop Not Echoing Line

Question

I have a problem here. First things first, the code:

Contents of test.bat:

@echo off
cls
for /F "delims=" %%a in ('dir /B /A-D ^| findstr /I ".txt$"') do (
set str=%%a
echo %str% >> list.tmp
pause
)

echo ------------------
for /F %%i in (list.tmp) do echo %%i
del list.tmp
echo ------------------

In the same directory where test.bat is, there are two test files: 1.txt and 2.txt

When I run test.bat, my output is:

------------------
2.txt
2.txt
------------------

As you can see, 1.txt isn't listed.

And when adding a 3.txt, the output is:

------------------
3.txt
3.txt
3.txt
------------------

Can anyone help me please??

Thanks, Andrew Wong

Jay · Accepted Answer · 2012-10-28 07:43:45Z

5

You'll need to use Delayed Expansion feature, since within a FOR loop, you're reading a variable, and that variable is also modified in that loop.

@echo off
setlocal enabledelayedexpansion
cls
for /F "delims=" %%a in ('dir /B /A-D ^| findstr /I ".txt$"') do (
  set str=%%a
  echo !str! >> list.tmp
  pause
)

echo ------------------
for /F %%i in (list.tmp) do echo %%i
del list.tmp
echo ------------------

answered Oct 28, 2012 at 7:43

Jay

4,6821 gold badge24 silver badges31 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Ulrich Freiberg · Accepted Answer · 2012-10-28 08:33:36Z

3

You could also use a function (subRoutine)... That also "force" CMD to evaluate for each loop...

@echo off
cls
for /F "delims=" %%a in ('dir /B /A-D ^| findstr /I ".txt$"') do (
  call :doOne %%a 
)

echo ------------------
for /F %%i in (list.tmp) do echo %%i
del list.tmp
echo ------------------
goto :EOF

:DoOne
  set str=%1
  echo %str% >> list.tmp
  pause

answered Oct 28, 2012 at 8:33

Ulrich Freiberg

661 bronze badge

Collectives™ on Stack Overflow

Batch Files, For Loop Not Echoing Line

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related