How do I extract all array values from a hash of hashes

Question

Newbie here. Aplogies if I am missing details.

In perl 5

I have a file that kind of looks like this

precedence = 2
new york
new jersey
florida
precedence = 3
kings
essex
dade
precedence = 1
brooklyn
newark
miami

I have no problem looping through the file and creating a $var that holds the value of precedence and an array (@tmp) that holds the lines until the next "section" (precedence = x)

I need to ultimately push all the sections into a final array in the order of the preference

so

print @final;

results in

 brooklyn
 .....
 new york
 .....
 kings
 .....

NOTE: I never know in advance how many sections there will be or how many lines each section will have

I thought perhapes to make a Hash of hashes and put each array in the HoH

push @{ $hash{"section_2"} }, @tmp ;

but I didnt know

a) if there would be a problem reusing the @tmp array each time i load a section in (after blanking it at the beginning of each loop)

b) I couldnt figure out how to get all values in the array in key "section_2" and push them into @final

Of course there may be a better approach.

ikegami · Accepted Answer · 2013-02-11 18:51:47Z

2

An HoH makes no sense. You could use an HoA if you expect a wide variance in precedence levels (1, 1000000, 1000000000),

my $precedence = 0;
my %data;
while (<>) {
   chomp;
   if (/precedence\s*=\s*([0-9]+)\z/) {
      $precedence = $1;
      next;
   }

   push @{ $data{$precedence} }, $_;
}

my @final = map @{ $data{$_} }, sort { $a <=> $b } keys %data;

but an AoA would most likely be a better fit.

my $precedence = 0;
my @data;
while (<>) {
   chomp;
   if (/precedence\s*=\s*([0-9]+)\z/) {
      $precedence = $1;
      next;
   }

   push @{ $data[$precedence] }, $_;
}

my @final = map @$_, grep $_, @data;

answered Feb 11, 2013 at 18:51

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

amphibient Over a year ago

i know you like to collapse many things in one line of code but i think it reads easier if you store the logically separate precedence value in its own distinct space in the data structure and the array of values in another rather than cannonically reserve the 1st array element for the precedence value and the rest are array values. but then again, I have attention span problems and i have to make my code super readable -- most perl programmer jam too much functionality on a single line, i can't follow it.

ikegami Over a year ago

@foampile, I didn't reserve the 1st array element as you say. I did store the logically separate precedence value in its own distinct space in the data structure as you suggested I should have done. Every element of the top level hash or array is a reference to an array. The referenced arrays only contain the name of the cities.

ikegami Over a year ago

@foampile, I really can't usefully break down the part you didn't understand, push @{ $data[$precedence] }, $_;.

eramm Over a year ago

Thanks ! I will try to build on your advice.

amphibient · Accepted Answer · 2013-02-11 19:06:51Z

0

Not really sure that I fully understand what you are trying to accomplish but if you want to print each precedence value and then the values from its array, you can try this:

my $hoh;

#This is not how you populate your HoH, I hard code it to simplify
@{$hoh->{2}->{'ARRAY'}} = ('new york', 'new jersey', 'florida');
@{$hoh->{3}->{'ARRAY'}} = ('kings', 'essex', 'dade');
@{$hoh->{1}->{'ARRAY'}} = ('brooklyn', 'newark', 'miami');

foreach my $prcdnc(keys(%$hoh))
{
    print "\nprcdnc = ".$prcdnc;

    my @prcdncAry = @{$hoh->{$prcdnc}->{'ARRAY'}};

    my $prcdncAryStr = join(",", @prcdncAry);

    print "\n\t".$prcdncAryStr;
}

answered Feb 11, 2013 at 19:06

amphibient

31.7k56 gold badges159 silver badges254 bronze badges

6 Comments

ikegami Over a year ago

All the ->{'ARRAY'} are useless. There's no reason to create a hash of one element for each precedence.

ikegami Over a year ago

This doesn't actually produce the desired result, an array with the values sorted by precedence.

ikegami Over a year ago

@{ $foo } = ( LIST ); is a silly way of doing $foo = [ LIST ];

ikegami Over a year ago

Why does name your variables "array foo array" (e.g. @prcdncAry)?

ikegami Over a year ago

Why does is an array of cities named @prcdncAry?

|

Collectives™ on Stack Overflow

How do I extract all array values from a hash of hashes

2 Answers 2

4 Comments

6 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

6 Comments

Your Answer

Sign up or log in

Post as a guest

Related