Cypher query with does not return anything if second part does not work

Question

I have a query which supposes to join two results and give the union as output.

MATCH (:Some )-[r*0..1]-> (p:Address) WITH collect(p) AS rows1
MATCH (:Some2)-[r*0..1]-> (pp:Address) 
WITH  rows1+collect(pp) AS rows2 
UNWIND rows2 AS row RETURN  row

As you can see the selection has two parts. So it works fine if there is matching data for both queries but if the second part of the match does not return anything then it returns empty. Meaning MATCH (:Some2)-[r*0..1]-> (pp:Address) returns empty then the whole union fails and returns null even if MATCH (:Some )-[r*0..1]-> (p:Address) return values .

How to fix this? Is it a bug in neo4j?

cybersam · Accepted Answer · 2018-06-04 19:33:12Z

2

This simple query should work:

MATCH (s)-[*0..1]->(p:Address)
WHERE s:Some OR s:Some2
RETURN p;

answered Jun 4, 2018 at 19:33

cybersam

67.3k6 gold badges59 silver badges81 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Tom Geudens · Accepted Answer · 2018-06-04 12:32:20Z

0

You have not actually asked a question (you have indeed just described the expected behaviour for pattern matching ... namely that if there is no match there is no result) ... but I assume you want a solution ?

MATCH (:Some )-[r*0..1]-> (p:Address)
RETURN p
UNION
MATCH (:Some2 )-[r*0..1]-> (p:Address)
RETURN p

should do the trick. Note that the only thing that matters is that the variables returned are exactly the same (what they contain doesn't actually matter).

Also ... you might want to have a look at what OPTIONAL MATCH does ...

Hope this helps.

Regards, Tom

Update

CALL apoc.cypher.run("
    MATCH (:Some )-[r*0..1]-> (p:Address)
    RETURN p
    UNION
    MATCH (:Some2 )-[r*0..1]-> (p:Address)
    RETURN p",{}) YIELD value
RETURN value.p AS result
ORDER BY result;

edited Jun 4, 2018 at 12:32

answered Jun 4, 2018 at 12:25

Tom Geudens

2,67611 silver badges15 bronze badges

2 Comments

Abdullah Al Noman Over a year ago

i tried with an optional match .. Is it a bug ? the normal union does not work for me because that does not work with count. I want this to return aggregated count also

Tom Geudens Over a year ago

Then wrap the whole statement in an apoc.cypher.run and you can postprocess all you want ... I updated my answer to show an example.

Abdullah Al Noman · Accepted Answer · 2018-06-07 08:30:10Z

0

Thanks for your inputs I used following version

MATCH (p:Address)
WHERE exist ((:Some )-[r*0..1]-> (p)) OR ((:Some2 )-[r*0..1]-> (p))
RETURN p;

answered Jun 7, 2018 at 8:30

Abdullah Al Noman

2,8884 gold badges22 silver badges37 bronze badges

Comments

marc_s · Accepted Answer · 2025-11-26 20:49:25Z

0

I had a very similar problem and this is the answer they gave to me. Basically when you do

// ...
WITH rows1 + collect(pp) AS rows2
// ...

You're involuntarily grouping by rows1, and groups get automatically skipped if they have no element.

If you wanted to change your query as little as possible to do what you wanted, you could just do this

MATCH (:Some)-[r*0..1]->(p:Address)
WITH collect(p) AS rows1
CALL () {
  MATCH (:Some2)-[r*0..1]->(pp:Address)
  RETURN collect(pp) AS rows3
}
WITH rows1 + rows3 AS rows2
UNWIND rows2 AS row
RETURN row

But I advise using one of the better solutions that have already been provided in the other answers

edited Nov 26 at 20:49

marc_s

760k186 gold badges1.4k silver badges1.5k bronze badges

answered Nov 13 at 19:00

AFatNiBBa

1675 bronze badges

Collectives™ on Stack Overflow

Cypher query with does not return anything if second part does not work

4 Answers 4

Comments

2 Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related