Is there a way to avoid using 'call' in Coffeescript?

Question

I'm writing a simple Twitter client to play with coffeescript. I have an object literal with some functions that call each other via callbacks.

somebject =
  foo: 'bar'
  authenticateAndGetTweets: ->
    console.log "Authorizing using oauth"
    oauth = ChromeExOAuth.initBackgroundPage(this.oauthdetails)
    oauth.authorize( this.afterLogin.call this )
  afterLogin: ->
    this.getTweets(this.pollinterval)

~~This code works perfectly.~~ Edit: actually this.afterlogin should be sent as a callback above, not ran immediately, as Trevor noted below.

If, within authenticateAndGetTweets, I removed the 'call' and just ran:

oauth.authorize( this.afterLogin )

and don't use 'call', I get the following error:

Uncaught TypeError: Object [object DOMWindow] has no method 'getTweets

Which makes sense, since 'this' in afterLogin is bound to the thing that initiated the callback rather than 'someobject' my object literal.

I was wondering if there's some magic in Coffeescript I could be doing instead of 'call'. Initially I thought using the '=>' but the code will give the same error as above if '=>' is used.

So is there a way I can avoid using call? Or does coffeescript not obviate the need for it? What made '=>' not work how I expected it to?

Thanks. I'm really enjoying coffeescript so far and want to make sure I'm doing things 'the right way'.

I did, but didn't understand your code. this.afterLogin.call this calls it immediately (it's identical to @afterLogin()), where this.afterLogin retrieves the function. Are you sure you aren't looking for Function::bind? — matyr
– matyr, Commented May 28, 2011 at 18:51
Matyr I mentioned I was already using 'call' in the title of the question, so saying 'use call' wasn't really much of an answer. Your second question makes a good point though: I'm actually running a function rather than specifying a function to run as a callback (which is what I want to do). I'll check this out now. — mikemaccana
– mikemaccana, Commented May 29, 2011 at 15:14
Uh yes, I meant "Why .call? You mean .bind?" Sorry for confusing you further. — matyr
– matyr, Commented May 30, 2011 at 3:08

Trevor Burnham · Accepted Answer · 2011-05-29 16:08:36Z

3

As matyr points out in his comments, the line

oauth.authorize( this.afterLogin.call this )

doesn't cause this.afterLogin to be called as a callback by oauth.authorize; instead, it's equivalent to

oauth.authorize this.afterLogin()

Assuming that you want this.afterLogin to used as a callback by oauth.authorize, megakorre's answer gives a correct CoffeeScript idiom. An alternative approach supported by many modern JS environments, as matyr points out, would be to write

oauth.authorize( this.afterLogin.bind this )

There's no CoffeeScript shorthand for this, partly because Function::bind isn't supported by all major browsers. You could also use the bind function from a library like Underscore.js:

oauth.authorize( _.bind this.afterLogin, this )

Finally, if you were to define someobject as a class instead, you could use => to define afterLogin such that it's always bound to the instance, e.g.

class SomeClass
  foo: 'bar'
  authenticateAndGetTweets: ->
    console.log "Authorizing using oauth"
    oauth = ChromeExOAuth.initBackgroundPage(this.oauthdetails)
    oauth.authorize(this.afterLogin)
  afterLogin: =>
    this.getTweets(this.pollinterval)

someobject = new SomeClass

edited May 29, 2011 at 16:08

answered May 29, 2011 at 0:38

Trevor Burnham

77.5k33 gold badges165 silver badges200 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

mikemaccana Over a year ago

Thanks Trevor for your comprehensive answer: I do actually want this.afterLogin to be run as a callback, with 'this' set to the object the afterlogin is part of.

Trevor Burnham Over a year ago

Cool, see expanded answer for a couple more ideas.

mikemaccana Over a year ago

Thanks again Trevor: using an object literal vs using a class also answers my second question re: why => wasn't working as I expected.

megakorre · Accepted Answer · 2011-05-28 18:08:53Z

3

you can put a lambda in the function call like so

auth.authorize(=> @afterLogin())

answered May 28, 2011 at 18:08

megakorre

2,22316 silver badges23 bronze badges

1 Comment

mikemaccana Over a year ago

Thanks, wrapping in a lambda works too - upboat! However in this case I always want the function to be called with this as the object it's a property of, so @Trevor's suggestion of using a class and => is more appropriate.

Maz · Accepted Answer · 2011-05-28 18:07:20Z

0

You have to use either the call or apply methods because they set the scope of the function (the value of this). The error results because the default scope is the window object.

answered May 28, 2011 at 18:07

Maz

3,3751 gold badge24 silver badges29 bronze badges

Collectives™ on Stack Overflow

Is there a way to avoid using 'call' in Coffeescript?

3 Answers 3

3 Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related