Convert async computation to .NET task without creating a new thread

Question

I am learning F# through building an ASP.NET Core app. I need to implement an interface Microsoft.AspNetCore.Identity.IUserStore<'TUser>; this interface features methods that return Task like:

member this.CreateAsync (user : User, cancellationToken : CancellationToken) =
    async {
        let connectionString = configuration.GetConnectionString("SocialScoreApp")
        let! rowCountResult = user |> createAsync connectionString
        match rowCountResult with
        | Ok _ -> return IdentityResult.Success
        | Error e ->
        let identityError = new IdentityError()
        identityError.Description <- e
        return IdentityResult.Failed(identityError)
    } |> Async.StartAsTask

But, according to the documentation, Async.StartAsTask "executes a computation on the thread pool". But this is an I/O bound operation so I don't want any new threads involved. Is there any way to achieve that?

Edit: This is the createAsync code for reference:

let createAsync (connectionString : string) (user:User) =
    let sql = "..."
    let args = dict [
        // ...
    ]
        
    async {
        use connection = new SqlConnection(connectionString)
        do! connection.OpenAsync() |> Async.AwaitTask

        try
            let! rowCount = connection.ExecuteAsync(sql, args) |> Async.AwaitTask
            return Ok rowCount
        with
        | e -> return Error e.Message
    }

Tasks aren't threads. They're essentially the same as an async computation - a promise that something will complete in the future. You already use Tasks in the async computation. Asynchronous ADO.NET methods return a Task — Panagiotis Kanavos
– Panagiotis Kanavos, Commented Jun 25, 2021 at 8:47
I know tasks aren't threads. But Async.StartAsTask does seem to start the computation on another thread according to how I interpret the documentation. If I remove |> Async.StartAsTask I get an error, because the return type is Async<IdentityResult> instead of Task<IdentityResult> — vladek
– vladek, Commented Jun 25, 2021 at 8:57
Async and Task instances are different regarding when they are run : Async is run on demand but Task is run immediately. So it's not possible to create a Task without the "I/O effect" that bathers you. — Romain Deneau
– Romain Deneau, Commented Jun 25, 2021 at 11:42

Tomas Petricek · Accepted Answer · 2021-06-25 09:37:20Z

4

If you look at how things work, the StartAsTask (source) operation creates a TaskCompletionSource, which creates a task that is returned to the caller. This is later used to report the result of the computation. In the meantime, the computation is started using QueueAsync, which invokes QueueWorkItemWithTrampoline (source) and this uses standard .NET ThreadPool.QueueUserWorkItem.

This means that when you run StartAsTask, the async workflow is added to the thread pool. However, the key thing for IO-bound operations is that you are using let! in your snippet:

let connectionString = configuration.GetConnectionString("SocialScoreApp")
let! rowCountResult = user |> createAsync connectionString

The work item added to the thread pool will only run GetConnectionString. It will then call createAsync, which presumably contains some non-blocking IO operation. As soon as the evaluation gets to this point, the work in the thread pool completes and it schedules a callback to be called when the IO operation completes - the callback is invoked later and adds the rest of the computation to thread pool as a new work item. So, you are not blocking the thread pool while the IO operation is running.

answered Jun 25, 2021 at 9:37

Tomas Petricek

244k22 gold badges397 silver badges563 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

vladek Over a year ago

Thank you Tomas, on spot as always! Added the createAsync code for reference.

Collectives™ on Stack Overflow

Convert async computation to .NET task without creating a new thread

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related