Problem saving string variables in .bat script

Question

As the title says I have a problem saving (and therefore printing) string variables in my bat script. The problem occurs when I try working with strings that start and/or end with '!'. Example:

@echo off
pause
setlocal ENABLEDELAYEDEXPANSION
for /r %%f in (*.png *.jpg *.gif *.webp *.jpeg) do (

set curr_name=%%~nxf
set curr_path=%%~dpf

@echo !curr_path!!curr_name!

@echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
)
pause

For file named !a.png and a!.png it prints out a.png and for !a!.png it just prints out .png. I've been trying to find answer for this but no luck. Sorry if I'm missing something obvious here and thanks for any tips!

T3RR0R · Accepted Answer · 2021-12-01 01:23:24Z

1

With delayed expansion enabled, this is expected behaviour. your shown use case does not require variables to be assigned - you could just use the relevant For variable modifiers.

If for some reason you need to use delayed expansion (for exmple performing substring modification), delayed expansion should be toggled on / off during the loop after the variable has been assigned:

Example:

@echo off

 for /r %%f in (*.png *.jpg *.gif *.webp *.jpeg) do (
  set "curr_name=%%~nxf"
  set "curr_path=%%~dpf"
  Setlocal enabledelayedexpansion
  echo(!curr_path!!curr_name!
  endlocal
  @echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 )

pause

edited Dec 1, 2021 at 1:23

answered Dec 1, 2021 at 0:31

T3RR0R

2,9813 gold badges14 silver badges27 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

user10820441 Over a year ago

The example I posted was the gutted part of the full script and I do need delayed expansion outside and inside this for loop. Do you suggest wrapping every part that needs it with setlocal enabledelayedexpansion/endlocal?

Compo Over a year ago

That would depend upon the rest of your 'gutted' code, which we cannot see. Enabling it for the entire script would generally be fine, as long as you will not need to use strings containing exclamation points, otherwise, enable it and use it only where required.

Collectives™ on Stack Overflow

Problem saving string variables in .bat script

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related