In Delphi 10 Seattle, I am trying to parse a JSON that contains an array of strings in a property.
As an example, consider this:
{
"name":"Joe",
"age":45,
"languages":["c++", "java", "cobol"]
}
How do I parse languages to obtain an array of strings?
Try something like this:
function GetLanguagesArray(const AJSON: String): TArray<String>;
var
LValue: TJSONValue;
LArray: TJSONArray;
i: Integer;
begin
Result := nil;
LValue := TJSONObject.ParseJSONValue(AJSON);
if LValue <> nil then
try
LArray := (LValue as TJSONObject).GetValue('languages') as TJSONArray;
SetLength(Result, LArray.Count);
for i := 0 to Pred(LArray.Count) do
begin
Result[i] := LArray[i].Value;
end;
finally
LValue.Free;
end;
end;
Very easy with REST.JSON, using helper to parse and read array items
type
TDeveloper = class
private
FAge : Integer;
FName : string;
FLanguages: TArray<string>;
public
property Age : Integer read FAge write FAge;
property Name : string read FName write FName;
property Languages: TArray<string> read FLanguages write FLanguages;
end;
// Sample
var
FDeveloper: TDeveloper;
FLanguage : string;
begin
try
FDeveloper := TJson.JsonToObject<TDeveloper>(Memo1.Text);
Memo2.Clear;
Memo2.Lines.Add('------------------------------ ');
Memo2.Lines.Add('Name: ' + FDeveloper.Name);
Memo2.Lines.Add('Age : ' + FDeveloper.Age.ToString);
for FLanguage in FDeveloper.Languages do
begin
Memo2.Lines.Add('------------------------------ ');
Memo2.Lines.Add(FLanguage);
end;
finally
FreeAndNil(FDeveloper);
end;
See image: [1]: https://i.sstatic.net/69Zao.png
function TForm1.GetLangArray(const AJSONStr: String): TArray<String>;
var
AJSONVal, AJSONElem: TJSONValue;
AJSONArray: TJSONArray;
i: Integer;
begin
AJSONVal := TJSONObject.ParseJSONValue(AJSONStr);
AJSONVal := AJSONVal.P['languages'];
if (AJSONVal is TJSONArray) then
AJSONArray := AJSONVal as TJSONArray
else
Exit;
with AJSONArray do
begin
SetLength(Result, Count);
i := 0;
for AJSONElem in AJSONArray do
begin
Result[i] := AJSONelem.Value;
Inc(i);
end;
end;
end;
UPDATE
thanks to @RemyLebeau for the comment. I fixed the memory leak of previous code:
function TForm1.GetLangArray(const AJSONStr: String): TArray<String>;
var
AJSONVal, AJSONElem: TJSONValue;
AJSONArray: TJSONArray;
i: Integer;
begin
AJSONVal := TJSONObject.ParseJSONValue(AJSONStr);
try
AJSONArray := AJSONVal.P['languages'] as TJSONArray;
with AJSONArray do
begin
SetLength(Result, Count);
i := 0;
for AJSONElem in AJSONArray do
begin
Result[i] := AJSONElem.Value;
Inc(i);
end;
end;
finally
AJSONVal.Free;
end;
end;
System.JSON is used?
TJSONValue.P[] property does not exist in 10.0 Seattle, it was added in 10.3 Rio. You will have to type-cast the parsed TJSONValue to TJSONObject and then use its Values[] property or GetValue() method to access the languages array. Also, this code is leaking the parsed TJSONValue returned from TJSONObject.ParseJSONValue(), you need to Free() it when you are done using it. Which means using a separate variable to retrieve the languages TJSONValue into.
TJSONObject