I think that there are actually three different parts to your question, and maybe your confusion is coming from combining them all together.

The way I see it is in these parts:

1. How to create a custom function.
2. How to apply a function to a new column.
3. How to apply a function to an existing column.

How to create a custom function

There are two main ways to create a custom function in Power Query:

1. Using the UI (follow steps here):

   Step	Description	Image
   1	Write your query
   2	Parameterise your query
   3	Create your function

2. Using only code (follow steps here):

   1. Example to filter a table:

      let fun_FilterTable = (tbl_InputTable as table, txt_FilterValue as text) as table =>
          let
              Source = tbl_InputTable,
              Filter = Table.SelectRows(DayCount, each Text.Contains([Column], txt_FilterValue))
          in
              Filter
      in
          fun_FilterTable
      

   2. Example to check if one string contains another:

      let fun_CheckStringContains = (txt_String as text, txt_Check as text) as nullable logical =>
          let
              Source = txt_String,
              Check = Text.Contains(Source, txt_Check)
          in
              Check
      in
          fun_CheckStringContains
      

More resources:

• Using custom functions
• Custom Functions Made Easy in Power BI Desktop
• PowerQuery best practices
• DataFlow best practices

How to apply a function to a new column

Also has two different ways to achieve:

1. Custom Column (follow steps here):

   Step	Description	Image
   1	Create custom column
   2	Add function

2. Custom Function (follow steps here):

   Step	Description	Image
   1	Invoke custom function

Sources:

• Add a custom column
• Using custom functions
• Custom Functions Made Easy in Power BI Desktop

How to apply a function to an existing column

Also has two different ways to achieve (unfortunately, only possible with pure code):

1. Using Transformation:
   1. Example to uppercase an entire column:

      let
          Source = Table,
          #"Uppercased text" = Table.TransformColumns(Source, {{"Column", each Text.Upper(_), type nullable text}})
      in
          #"Uppercased text"
      

   2. Example to add a prefix to all rows in one column:

      let
          Source = Table,
          #"Added prefix" = Table.TransformColumns(Source, {{"Column", each "test_" & _, type text}})
      in
          #"Added prefix"
      

   3. Example to coerce column to date in Australian format:

      let
          Source = Table,
          #"Fix date" = Table.TransformColumns(Source, {{"DateColumn", each Date.From(_, "en-AU"), type date}})
      in
          #"Fix date"
      

2. Using Replacement
   1. Example to replace some text:

      let
          Source = Table,
          #"Replaced value" = Table.ReplaceValue(Source, "Admin", "Administrator", Replacer.ReplaceText, {"Column"})
      in
          #"Replaced value"
      

   2. Example to replace with values from another column

      let
          Source = Table,
          #"Replaced value" = Table.ReplaceValue(Source, each [FixThisColumn], each [OtherColumn], Replacer.ReplaceText, {"FixThisColumn"})
      in
          #"Replaced value"
      

Your Specific Problem

Without some dummy data to use, I have created some here, so that we can easily recreate the scenario from your example.

Data:

I think that you should be using a combination of the PowerQuery in-build date functions (see here) and some of the PowerQuery conditional processes (see here).

My code would look something like this:

let
    Source = Table.FromColumns({{1,2,3,4,5},{"1/Jan/2020","1/Jan/2022","1/Mar/2022","1/Sep/2021","1/Jan/2023"},{"1/Dec/2021","1/Mar/2023","1/Dec/2022","1/Dec/2023","1/Dec/2023"}},{"ID","ProgramStartDate","ProgramEndDate"}),
    fix_Types = Table.TransformColumnTypes(Source,{{"ID", Int64.Type}, {"ProgramStartDate", type date}, {"ProgramEndDate", type date}}),
    add_Today = Table.AddColumn(fix_Types, "DateToday", each Date.From(DateTime.LocalNow()), type date),
    add_CheckCurrentYear = Table.AddColumn(add_Today, "IsInCurrentYear", each Date.IsInCurrentYear([DateToday]), type logical),
    add_CheckProgramRunning = Table.AddColumn(add_CheckCurrentYear, "ProgramIsCurrent", each [DateToday]>[ProgramStartDate] and [DateToday]<[ProgramEndDate], type logical),
    add_ConditionalCheck = Table.AddColumn(add_CheckProgramRunning, "DoSomething", each if [IsInCurrentYear] and [ProgramIsCurrent] then "Do Something" else null, type text)
in
    add_ConditionalCheck

And the final output would look something like this: