How to get a Part of the Directory path in a batch file

Question

I have a BAT file in a directory

D:\dir1\dir2\getpath.bat

when i run the bat with the below code it prints

D:\dir1\dir2\

i want only the path D:\dir1\

The directory structure is not fixed , need the complete directory path other than the current directory in which BAT file resides.

@echo off
SET SUBDIR=%~dp0
ECHO %SUBDIR%

tried using delims in a for loop but it didnt help.

I don't think I fully understand. What exactly are you trying to do? What specifies your "complete directory path"? Let's say you move your script to F:\other\bins\own, what should be your output? F:\other\bins\ , F:\other\ or something else entirely? — SvenS
– SvenS, Commented Sep 23, 2011 at 10:35

Arun · Accepted Answer · 2011-10-04 15:35:58Z

3

@echo off
setlocal
SET SUBDIR=%~dp0
call :parentfolder %SUBDIR:~0,-1% 
endlocal
goto :eof

:parentfolder
echo %~dp1
goto :eof

edited Oct 4, 2011 at 15:35

answered Sep 23, 2011 at 16:51

Arun

2,55316 silver badges12 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

Anthony Miller Over a year ago

if %~dp0=C:\dir1\dir2 setting %SUBDIR:~0,-1% will turn it into C:\dir1\dir. Given if the OP doesn't have directories with the same name in a single numbered sequence, this doesn't solve his problem.

Arun Over a year ago

@Mechaflash: Did you try this at your end? Well what you said isn't the final step. The value "C:\dir1\dir" is passed to another routine which does ECHO. It will work perfectly if you try running

Richard A Over a year ago

I like this answer. It'd be good practice to bracket the code with setlocal/endlocal so that SUBDIR isn't available outside the batch file context.

Arun Over a year ago

@RichardA Thanks Richard. Edited to include localization.

Richard A Over a year ago

@Arun, I hope you don't think I was being picky. Oh, the endlocal is one line too low, should be before the goto :eof.

|

SvenS · Accepted Answer · 2011-10-04 06:34:22Z

1

If it's the parent directory of the directory your script resides in you want, then try this:

@echo off
SET batchdir=%~dp0
cd /D "%batchdir%.."
echo %CD%
cd "%batchdir%"

(untested, please comment if there are problems)

Note that this will, of course, change nothing if your batch resides in your drive root (as in F:\) ;) If you'd like a special output if that's the case, you should test %CD% against %batchdir% before the echo.

EDIT: Applied patch, see comment by @RichardA

edited Oct 4, 2011 at 6:34

answered Sep 23, 2011 at 10:41

SvenS

7947 silver badges15 bronze badges

2 Comments

Richard A Over a year ago

Will this work when run from a different directory or a different drive? Would pushd/popd be simpler than saving off batchdir?

SvenS Over a year ago

Oh, you're right, I'll edit in a patch. %~dp0 is not the working directory but the directory the batch resides in (source), so you need to cd into that dir first (if that's what is desired). I can't really say anything to pushd/popd.

MattyG · Accepted Answer · 2011-09-23 10:37:11Z

1

@echo off
SET MYDIR=%cd%
cd %MYDIR%\..
SET MYPARENTDIR=%cd%
cd %MYDIR%

answered Sep 23, 2011 at 10:37

MattyG

663 bronze badges

Comments

dbenham · Accepted Answer · 2012-08-31 04:07:14Z

1

A single line of code does it :-)

If you want the trailing back slash, then

for %%A in ("%~dp0.") do @echo %%~dpA

If you don't want the trailing back slash, then

for %%A in ("%~dp0..") do @echo %%~fA

answered Aug 31, 2012 at 4:07

dbenham

132k29 gold badges273 silver badges410 bronze badges

1 Comment

dbenham Over a year ago

Why on earth would someone down vote this? It gives the correct answer, and is very efficient, both from the standpoint of amount of code, as well as performance.

M P · Accepted Answer · 2014-02-19 20:18:59Z

0

%~dp0 returns the full drive letter and path of the current batch file. This can be used in a FOR command to obtain portions of the path:

When run from C:\dir1\dir2\dir3\batch.bat

FOR %%V IN ("%~dp0..\") DO @ECHO %%~dpV

returns C:\dir1\dir2\

This can be extended to continue higher up the path:

FOR %%V IN ("%~dp0..\..\") DO @ECHO %%~dpV

returns C:\dir1\

Source: Microsoft info on batch parameters

answered Feb 19, 2014 at 20:18

M P

261 bronze badge

Comments

Anthony Miller · Accepted Answer · 2011-09-23 14:04:23Z

-1

You almost had it right. Using %~dp0 grabs the Drive+Full path to your .bat so it will return the folder which your bat file is located in as well.

Since the active directly will be the directory your bat is run from, all you'll need to do is:

@echo off
CD ..
SET SUBDIR=%CD%
ECHO %SUBDIR%

If putting this in a bat script to verify, throw in a PAUSE on a newline to see your output.

answered Sep 23, 2011 at 14:04

Anthony Miller

16.1k30 gold badges74 silver badges101 bronze badges

1 Comment

Richard A Over a year ago

Why will the active directory be the directory your bat is run from? What if he calls it the active directory is c:\ and he runs D:\dir1\dir2\getpath.bat? Wont the active directly by c:\?

Collectives™ on Stack Overflow

How to get a Part of the Directory path in a batch file

6 Answers 6

6 Comments

2 Comments

Comments

1 Comment

Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

6 Comments

2 Comments

Comments

1 Comment

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest