tests/auto/quickcontrols/qquickcontextmenu/data/sharedContextMenuOnRectangle.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Controls.Basic
import QtQuick.Templates as T

ApplicationWindow {
    width: 600
    height: 400

    Menu {
        id: contextMenu

        readonly property string triggerItemText: (parent as T.Label)?.text ?? ""

        MenuItem {
            text: qsTr("Eat %1").arg(contextMenu.triggerItemText)
        }
        MenuItem {
            text: qsTr("Throw %1").arg(contextMenu.triggerItemText)
        }
        MenuItem {
            text: qsTr("Squash %1").arg(contextMenu.triggerItemText)
        }
    }

    component Tomato: Label {
        id: root
        objectName: text
        horizontalAlignment: Label.AlignHCenter
        verticalAlignment: Label.AlignVCenter
        width: Math.max(200, contentWidth * 1.5, contentWidth * 1.5)
        height: width
        color: skinColor

        property color skinColor: "tomato"

        background: Rectangle {
            color: root.skinColor
            radius: width / 2
        }

        ContextMenu.menu: contextMenu
    }

    Row {
        anchors.centerIn: parent

        Tomato {
            text: qsTr("tomato")
        }

        Tomato {
            text: qsTr("really ripe tomato")
            skinColor: "maroon"
        }
    }
}