Populate data with ratio to previous element

Question

I have a data which looks like this {x,y}:

data={{1,3},{2,4},{3,5},{4,6}}

I need to add another column and define it as current element divided by previous element.

This could be done like this:

For[i = 1, i <= Length[data], i++, 
 If[i == 1, data[[i]] = Append[data[[i]], 1], 
 data[[i]] = Append[data[[i]], data[[i, 2]]/data[[i - 1, 2]]]]]

However, I think that in Mathematica there may be a better way to do it

What is the easiest way to do this in Mathematica?

Is there any rule about the first element in a new column or is it always 1? — Kuba
– Kuba, Commented May 16, 2017 at 11:11

Kuba · Accepted Answer · 2017-05-16 11:18:07Z

4

Join[
    data
  , List /@ Prepend[Ratios @ data[[;; , 2]], 1]
  , 2
]

answered May 16, 2017 at 11:18

Kuba

139k13 gold badges297 silver badges803 bronze badges

ZaMoC · Accepted Answer · 2017-05-16 11:12:06Z

2

Join[{AppendTo[data[[1]], 1]}, 
Table[{data[[i]][[1]], data[[i]][[2]], 
data[[i]][[2]]/data[[i - 1]][[2]]}, {i, 2, Length@data}]]

{{1, 3, 1}, {2, 4, 4/3}, {3, 5, 5/4}, {4, 6, 6/5}}

answered May 16, 2017 at 11:12

ZaMoC

6,80715 silver badges32 bronze badges

Ali Hashmi · Accepted Answer · 2017-05-16 14:27:35Z

2

Flatten[Riffle[#, Ratios@Prepend[#2 & @@@ #, Last@First[#]]], 1]&@data~Partition~3
(* {{1, 3, 1}, {2, 4, 4/3}, {3, 5, 5/4}, {4, 6, 6/5}} *)

answered May 16, 2017 at 14:27

Ali Hashmi

9,1304 gold badges23 silver badges44 bronze badges

ubpdqn · Accepted Answer · 2017-05-17 04:07:52Z

2

Transpose[{#1, #2, {1}~Join~Ratios[#2]} & @@ Transpose[data]]

answered May 17, 2017 at 4:07

ubpdqn

67.8k3 gold badges66 silver badges164 bronze badges

4 Answers 4