Use sequence-functions to find certain sublists

Question

I want to split a list of positive Integers into sublists whose ascending elements differ by 1.

list = {1, 0, 1, 0, 1, 4, 5, 6, 5, 8, 1, 2};

This can be done easily using Split

Split[list, #2 - #1 == 1 &]

{{1}, {0, 1}, {0, 1}, {4, 5, 6}, {5}, {8}, {1, 2}}

But how can we get the same result

(a) with one of the Sequence-functions (SequenceCases, SequenceSplit or SequencePosition) - or, if this is not possible,

(b) What other options do we have?

vindobona · Accepted Answer · 2024-03-20 22:15:11Z

4

Using SequenceCases with a similar condition like the one for Split:

list = {1, 0, 1, 0, 1, 4, 5, 6, 5, 8, 1, 2};

SequenceCases[list, s_ /; OrderedQ[s, #2 - #1 == 1 &]]

{{1}, {0, 1}, {0, 1}, {4, 5, 6}, {5}, {8}, {1, 2}}

answered Mar 20, 2024 at 22:15

vindobona

8,3161 gold badge18 silver badges38 bronze badges

Syed · Accepted Answer · 2024-03-20 12:10:46Z

5

list = {1, 0, 1, 0, 1, 4, 5, 6, 5, 8, 1, 2};

Using SequenceReplace or SequenceCases:

SequenceReplace[list, {b__ /; 
    ContainsOnly[Differences[{b}], {1}]} :> {b}]

Result:

{{1}, {0, 1}, {0, 1}, {4, 5, 6}, {5}, {8}, {1, 2}}

The documentation says:

ContainsOnly[{},list] always returns True

without which this would not be possible.

answered Mar 20, 2024 at 12:10

Syed

62.9k5 gold badges48 silver badges104 bronze badges

E. Chan-López · Accepted Answer · 2024-03-20 22:31:57Z

3

list = {1, 0, 1, 0, 1, 4, 5, 6, 5, 8, 1, 2};

Using SequenceSplit with the following condition:

SequenceSplit[list, s : {b__ /; MatchQ[Differences[{b}], {1 ...}]} :> s]

{{1}, {0, 1}, {0, 1}, {4, 5, 6}, {5}, {8}, {1, 2}}

answered Mar 20, 2024 at 22:31

E. Chan-López

33.7k3 gold badges34 silver badges54 bronze badges

3 Answers 3