Trigger to copy child object picklist values to parent object separated by comma

The code you have shared will not at all compile.

• use close brace here for (Opportunity childObj : Trigger.new)
• use childObj.AccountId instead of childObj.Account to access AccountId
• When you use relationship query be sure to use Opportunities instead of Opportunity.
• You should put Opportunity's Opp_Location__c into a List. Then use String.join() to add those with comma delimited.
• And finally update accounts.

Trigger

trigger UpdateAmount on Opportunity (after insert, after update) { 
  Map<ID, Account > parentOpps = new Map<ID, Account>(); 
  Set<Id> listIds = new Set<Id>();

  for (Opportunity childObj : Trigger.new) {
    listIds.add(childObj.AccountId);
  }

  parentOpps = new Map<Id, Account>([SELECT id, Location_Type__c ,
                                        (SELECT ID, Opp_Location__c  FROM Opportunities) 
                                    FROM Account WHERE ID IN :listIds]);

  List<Account> lstAccount = new List<Account>();

  for(Account acct:parentOpps.values())
  {  
      List<String> strType = new List<String>();
      for(Opportunity oppty:acct.Opportunities)
      {
          strType.add(oppty.Opp_Location__c);
      }
      acct.Location_Type__c = String.join(strType,',');

  }

  update parentOpps.values();
}