Perl: inserting array of arrays in into a array which is a value for a key

Question

I have a need of inserting an array of arrays into an array.And this whole array is a value for a key in a hash.i meant hash should look like this:

"one"
[
  [
    1,
    2,
  [
    [
      3,
      4
    ],
    [
      5,
      6
    ]
  ]
]
]

where one is the key here and remaining part if the value of for that key in the hash. observe that the array of arrays [3,4] and [5,6] is the third element in the actual array. the first two elements are 1 and 2.

I have written a small program for doing the same.

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;
$Data::Dumper::Terse = 1;
$Data::Dumper::Indent = 1;
$Data::Dumper::Useqq = 1;
$Data::Dumper::Deparse = 1;

my %hsh;
my @a=[1,2];
my @b=[[3,4],[5,6]];
$hsh{"one"}=\@a;
push @{$hsh{"one"}},@b;
print Dumper(%hsh);

But this prints as below:

"one"
[
  [
    1,
    2
  ],   #here is where i see the problem.
  [
    [
      3,
      4
    ],
    [
      5,
      6
    ]
  ]
]

I can see that the array of arrays is not inserted into the array. could anybody help me with this?

[...] creates an array reference, not an array. So @a=[1,2] creates an array of one element. This may be a source of your problem, but I'm not sure: The intendation of your expected data structure was confusing. @a=(1,2) would create an array of two elements. Are you sure you dont want %hsh = ( one => [1, 2, [ 3, 4 ], [5, 6]] )? — amon
– amon, Commented Jun 6, 2013 at 6:08

ikegami · Accepted Answer · 2013-06-06 06:26:02Z

1

First, a note: Only pass scalars to Dumper. If you want to dump an array or hash, pass a reference.

Then there's the question of what you expect. You say you expect

[ [ 1, 2, [ [ 3, 4 ], [5, 6] ] ] ]

But I think you really expect

[ 1, 2, [ [ 3, 4 ], [5, 6] ] ]

Both errors have the same cause.

[ ... ]

means

do { my @anon = ( ... ); \@anon }

so

my @a=[1,2];
my @b=[[3,4],[5,6]];

is assigning a single element to @a (a reference to an anonymous array) an a single element to @b (a reference to a different anonymous array).

You actually want

my @a=(1,2);
my @b=([3,4],[5,6]);

So from

my %hsh;
$hsh{"one"}=\@a;
push @{$hsh{"one"}},@b;
print(Dumper(\%hsh));

you get

{
  "one" => [
    1,
    2,
    [
      3,
      4
    ],
    [
      5,
      6
    ]
  ]
}

answered Jun 6, 2013 at 6:26

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Nikhil Jain · Accepted Answer · 2013-06-06 06:40:23Z

0

use strict;
use warnings;
use Data::Dumper;
$Data::Dumper::Terse = 1;
$Data::Dumper::Indent = 1;
$Data::Dumper::Useqq = 1;
$Data::Dumper::Deparse = 1;

my %hsh;
my @a=(1,2); # this should be list not array ref
my @b=([3,4],[5,6]); # this should be list conatining array ref
push (@a, \@b); #pushing ref of @b
push (@{$hsh{'one'}}, \@a); #pushing ref of @a

print Dumper(%hsh);

Output:

Updated:

my %hsh;
my @a=( 1,2 );
my @b=( [3,4],[5,6] );
push (@a, @b); # removed ref of @b
push (@{$hsh{'one'}}, @a); #removed ref of @a

print Dumper(\%hsh);

Output:
{
  "one" => [
    1,
    2,
    [
      3,
      4
    ],
    [
      5,
      6
    ]
  ]
}

edited Jun 6, 2013 at 6:40

answered Jun 6, 2013 at 6:21

Nikhil Jain

8,3782 gold badges28 silver badges50 bronze badges

1 Comment

ikegami Over a year ago

Are you sure that's it? You seem to have an an extra array. See my answer.

Collectives™ on Stack Overflow

Perl: inserting array of arrays in into a array which is a value for a key

2 Answers 2

Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related