Perl: using array to create hash of hash structure

Question

within a loop I retreive

An array (its length and data might change at each iteration)
1 Data name
1 Data value

And I would like to create a hash of hash having as structure the array and set at the end the data retreived.

exemple if I have:

@array = ('a','b','c');
$dataname = 'my data';
$datavalue = '123';

I would like to have a hash as below:

%hash = (
     a => {
           b => {
                 c => {
                       'my data' => '123'
                      }
                }
          }
          );

But i didn't find anywhere how to do it.

Take a look at Data::Diver

Borodin
– Borodin

2017-02-08 16:38:47 +00:00
Commented Feb 8, 2017 at 16:38 — Borodin
– Borodin, Commented Feb 8, 2017 at 16:38

ikegami · Accepted Answer · 2017-02-08 16:54:57Z

3

use Data::Diver qw( DiveVal );

DiveVal(\%hash, map \$_, @array, $dataname) = $datavalue;

Alternatively,

sub DiveVal :lvalue {
   my $p = \shift;
   $p = \( $$p->{$_} ) for @_;
   $$p
}

DiveVal(\%hash, @array, $dataname) = $datavalue;

edited Feb 8, 2017 at 16:54

answered Feb 8, 2017 at 16:39

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

ikegami Over a year ago

@Hunter McMillen, Explanation of the above code. In particular, read "The extra level of indirection has many benefits" section.

ikegami Over a year ago

@Hunter McMillen, sub { my $r = shift; $r &&= $r->{$_} for @_; $r } would be fine if you wanted to fetch from the structure, but since we're adding to the structure, we need to end up with a reference to the last value. You can do that by handling the last key specially, but the extra level of indirection makes things so much easier.

ikegami Over a year ago

@Hunter McMillen, This does something similar, but uses aliases instead of references. Aliases using Data::Alias: sub DiveVal :lvalue { alias my $s = shift; alias $s = $s->{$_} for @_; $s }. Aliases using the refaliasing feature: sub DiveVal :lvalue { \my $s = \shift; \$s = \( $s->{$_} ) for @_; $s }.

Maximilien Over a year ago

@ikegami, Your soltion looks good but unfortunatly, that script must but run on a system on which I cannot install any additional modules and that module is not available on the target machine. I will try to find an other solution without creating the hash in that way

Nullman · Accepted Answer · 2017-02-09 20:07:43Z

-1

you can do it this way, its not the most efficient but it works

use Data::Dumper;

my @array = ('a','b','c');
my $dataname = 'my data';
my $datavalue = '123';

my $hash = {$dataname => $datavalue};

foreach my $item (reverse @array){
    $hash = {$item =>$hash};
}
my %hash =%$hash;
print Dumper(\%hash);

you will get the following output:

$VAR1 = {
          'a' => {
                   'b' => {
                            'c' => {
                                     'my data' => '123'
                                   }
                          }
                 }
        };

answered Feb 9, 2017 at 20:07

Nullman

4,2842 gold badges18 silver badges32 bronze badges

Collectives™ on Stack Overflow

Perl: using array to create hash of hash structure

2 Answers 2

4 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related