I want to check the current directory for the existence of files with extensions of abc, bak or tmp, or a file named tmpout.wrk. I can't get this (eventually part of a function) to work in zsh. It runs, but fails to detect properly.
if [[ -f *.(abc|bak|tmp) || -f tmpout.wrk ]]; then
echo 'true';
else
echo 'false';
fi
To test that the glob returns at least one file, you can do:
if ()(($#)) (*.(abc|bak|tmp)|tmpout.wrk)(NY1); then
echo true
else
echo false
fi
To check that at least one of them is a regular file after symlink resolution, add the -. glob qualifier:
if ()(($#)) (*.(abc|bak|tmp)|tmpout.wrk)(NY1-.); then
echo true
else
echo false
fi
()(($#)) is an anonymous functions to which we pass the result of the globs. The body of that function ((($#))) just tests that the number of arguments in non-zero.
N as a glob qualifier turns on nullglob for that glob (makes the glob expand to nothing when it doesn't match any file)
Y1 limits the expansion to at most one file. It's a performance optimization.
- makes the next glob qualifier be considered after symlink resolution.
. considers regular files only (so here regular files or symlinks eventually resolving to a regular file, like the [ -f file ] command does).
TL;DR
set -o extendedglob
if [[ -n *.(abc|bak|tmp)(#qN) || -f tmpout.wrk ]]; then
Otherwise, via some testing,
% [[ -f /etc/passwd ]] && echo yea
yea
% echo /etc/passw?
/etc/passwd
% [[ -f /etc/passw? ]] && echo yea
%
Okay, what is zsh doing here?
% set -x
% [[ -f /etc/passw? ]] && echo yes
+zsh:13> [[ -f '/etc/passw?' ]]
%
Them single quotes sure aren't going to glob nothing. Let's search on [[ in man zshall ... and then search on CONDITIONAL EXPRESSIONS ... ah here's something about filename generation:
Filename generation is not performed on any form of argument to condi-
tions. However, it can be forced in any case where normal shell expan-
sion is valid and when the option EXTENDED_GLOB is in effect by using
an explicit glob qualifier of the form (#q) at the end of the string.
A normal glob qualifier expression may appear between the `q' and the
closing parenthesis; if none appears the expression has no effect
beyond causing filename generation. The results of filename generation
are joined together to form a single word, as with the results of other
forms of expansion.
This special use of filename generation is only available with the [[
syntax. If the condition occurs within the [ or test builtin commands
then globbing occurs instead as part of normal command line expansion
before the condition is evaluated. In this case it may generate multi-
ple words which are likely to confuse the syntax of the test command.
For example,
[[ -n file*(#qN) ]]
produces status zero if and only if there is at least one file in the
current directory beginning with the string `file'. The globbing qual-
ifier N ensures that the expression is empty if there is no matching
file.
So with this in mind,
% [[ -f /etc/passw?(#q) ]] && echo yes
+zsh:14> [[ -f /etc/passwd ]]
+zsh:14> echo yes
yes
% exec zsh -l
And to your case, accounting for the case where there may be no files:
% mkdir dir
% cd dir
% touch blah.foo
% [[ -f *.(foo|bar|baz)(#q) ]] && echo yea
yea
% rm blah.foo
% [[ -f *.(foo|bar|baz)(#q) ]] && echo yea
zsh: no matches found: *.(foo|bar|baz)(#q)
% [[ -f *.(foo|bar|baz)(#qN) ]] && echo yea
% touch a.foo b.foo
% [[ -f *.(foo|bar|baz)(#qN) ]] && echo yea
% [[ -n *.(foo|bar|baz)(#qN) ]] && echo yea
yea
%
(though with -n we only check that the globs match, not that the corresponding files are regular files).
-f doesn't work if there's more than one file. Using -n and checking the type with a glob qualifier might work? (Well, there the -n was in the quote, too)
[[ -f *.(foo|bar|baz)(#qNY1-.) ]] && echo yea. Same end effect as yours, but optimized to stop globbing after finding a single match, looking for regular files only (after following symlinks). YMMV but this works to my advantage perfectly!
-fsuggests (after or before symlink resolution)?-fI should use-aor-e(unclear on the difference)? Thanks