Clojure: Debugging Println, __LINE_NUMBER and FILE_NAME__

Question

Context

Currently,

(println "x is" x)

just prints out

x is 10

Now, what I want is something like this:

(my-println "x is" x)

to print out:

foo.clj:23> x is 10

Informally, I want my-println to append the _FILE_NAME_ and _LINE_NUMBER_ into my println.

Question:

I know how to use macros. However, I don't know how to extract the _FILE_NAME_ and _LINE_NUMBER_ from the current location in Clojure (whereas C macros make this trivial to do). How do I get the current FILE_NAME_ and _LINE_NUMBER_ ?

Thanks.

amalloy · Accepted Answer · 2017-07-22 19:56:51Z

10

(defmacro my-println [x]
  `(do (printf "%s:%s> %s is %s\n"
               ~*file*
               ~(:line (meta &form))
               ~(pr-str x)
               ~x)
       (flush)))

Looking at this answer again much later, you can be a bit more clever if you like, reducing the runtime costs by interpolating the string constants at compile time:

(defmacro my-println [x]
  `(println ~(format "%s:%s> %s is"
                     *file*
                     (:line (meta &form))
                     (pr-str x))
            ~x))

As you can see from the macroexpansion, there is no longer any need to invoke relatively-expensive printf code at runtime:

(let [x 5] (macroexpand '(my-println (+ x 5))))
(clojure.core/println "foo.clj:1> (+ x 5) is" (+ x 5))

edited Jul 22, 2017 at 19:56

answered Jun 9, 2012 at 3:18

amalloy

93k8 gold badges149 silver badges216 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

user1383359 Over a year ago

whoa, I didnt' know clojure had printf -- no more crap like (println (apply str .... ))

number23_cn Over a year ago

if use lein run -m your.main.class or clojure.main -m your.main.class, the *file* is nil.

Juha Syrjälä · Accepted Answer · 2012-07-15 07:21:19Z

0

Java logging frameworks like log4j and logback provide this kind of functionality. You can configure logging system to add the line numbers to log messages. File name may be more difficult, but at least you can have the namespace there.

You can use clojure.logging to provide nice interface to the logging frameworks.

answered Jul 15, 2012 at 7:21

Juha Syrjälä

34.4k33 gold badges137 silver badges191 bronze badges

Collectives™ on Stack Overflow

Clojure: Debugging Println, __LINE_NUMBER and FILE_NAME__

Context

Question:

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

Context

Question:

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related