Oracle string literal too long - extraction of data within a string

Question

Using Oracle 11g, I have the following LDAP string which is only a subset of what I am trying to demonstrate here.

Basically I have a very long string that is causing me ‘string literal too long’ issues and basically within this string, I want to be able to either strip out the bits I don’t want or even better, strip out the only bits that I need.

This is only a short version of the string contents/length:

Member of = CN=aTIGERAdmin-Admin, CN=D0902498, CN=ea90045052, CN=aTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=aTIGERAdmin-Admin, CN=ea90045052, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=aTIGERCall-Admin, CN=aTIGERAdmin-Admin, CN=D0902498, CN=ea90045052, CN=aTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=aTIGERAdmin-Admin, CN=ea90045052, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=DAaTIGERCall-Admin, CN=aTIGERCall-Admin,

Assume the above is greater than 4000 characters long.

My issue is, using Oracle SQL and PL/SQL and the above “member of” string, I need to somehow filter out only the bits that look like ‘CN=aTIGER%’ and completely ignore entries that look like ‘CN=DAaTIGER%’ which I believe, we solve my string literal issues but I am unable to filter this out first as my original string is already greater than 4000 chars long.

Using pl/sql, I am seeking an approach that will only return the entries inside “member of” that look like ‘CN=aTIGER%’ and completely ignore entries that look like ‘CN=DAaTIGER%’ at the same time, ensure that there is also a comma at the end of the result.

Do I need to assign this to a CLOB and then process the entries I need?

How long is the literal causing the error? Did you try to split the string into a varray? — Iľja
– Iľja, Commented Jul 3, 2012 at 6:12

Tebbe · Accepted Answer · 2012-07-03 03:00:37Z

In the following code, I prepopulated a CLOB "c" with a bunch of data like your sample. I'm not sure what you want to do with each qualifying entry; I just DBMS_OUTPUT it.

Given all that, here's a stab at it:

SET SERVEROUTPUT ON
DECLARE
    c                   CLOB;
    l_offset            POSITIVE := 1;
    l_ldap_component    LONG;
    l_counter           NATURAL := 0;
BEGIN
    -- Set up the CLOB.  In real life, this data will come
    -- from some other source.
    c := 'Member of = CN=aTIGERAdmin-Admin'
      || ', CN=D0902498'
      || ', CN=ea90045052'
      || ', CN=aTIGERCall-Admin'
      || ', CN=DAaTIGERCall-Admin'
--- Lots of additional data excised for the sake of brevity....
      || ', CN=aTIGERCall-Admin,';
    DBMS_OUTPUT.PUT_LINE('Length of CLOB = ' || TO_CHAR(DBMS_LOB.GETLENGTH(c)));

    -- Search for commas within the CLOB, and extract each subsequent
    -- inter-comma string, including the trailing comma.
    WHILE (DBMS_LOB.INSTR(c,',',l_offset) > 0)
    LOOP
        l_ldap_component :=
            TRIM (
                DBMS_LOB.SUBSTR(c
                ,               DBMS_LOB.INSTR(c
                                ,              ','
                                ,              l_offset) - l_offset + 1
                ,               l_offset)
        );
        IF (l_ldap_component LIKE 'CN=aTIGER%,') THEN
            -- I'm printing the qualified entries to the screen, but you
            -- can add them to a collection or whatever....
            DBMS_OUTPUT.PUT_LINE(l_ldap_component);
        END IF;
        l_offset := DBMS_LOB.INSTR(c,',',l_offset) + 1;
    END LOOP;    
END;
/

With the data I used, this code produced the output:

Length of CLOB = 5127
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,
CN=aTIGERAdmin-Admin,
CN=aTIGERCall-Admin,

PL/SQL procedure successfully completed.

SQL>

I hope this helps.

Collectives™ on Stack Overflow

Oracle string literal too long - extraction of data within a string

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related