Batch File If statement inside For loop

Question

I am having the issue where my if statement (inside a for loop), doesn't seem to cooperate. What I am trying to do is this:

Loop through a bunch of zip files and rename them 005.zip, 006.zip, 007.zip, etc.
I keep a counter, starting at 5, that determines the file number, and a prefix that is 00 in order to get 005, 006, and so on.
Once the counter reaches 10, I want the prefix to just be 0 instead of 00. So when the counter is ten, that file will be named 010.zip, and then 011.zip instead of 0010.zip, 0011.zip etc.

Here is what I have thus far:

setlocal enableextensions enabledelayedexpansion
SET /a COUNT=5
SET FILE_PREFIX=00
SET /a MAX=10
for %%f in (*.zip) do  (
   if !COUNT! == !MAX! (set FILE_PREFIX=0)
   ren "%%f" %FILE_PREFIX%!COUNT!.zip
   set /a COUNT+=1
   echo !COUNT!
)
endlocal

Why doesn't the if statement work? The file renaming is working fine, it is just that if statement that doesn't change the FILE_PREFIX to 0.

If does work for me. Are you sure you have posted the very exact code you are running? — PA.
– PA., Commented Aug 1, 2012 at 15:11
Yeah it is definitely the same code..I double checked and ran it again, and I'm still getting files named 0010.zip, 0011.zip and so on. — Andrew Backes
– Andrew Backes, Commented Aug 1, 2012 at 15:18
oh I see what the problem is. You don't apply delayed expansion to the FILE_PREFIX. It was me who did not copy the very exact code. Sorry. Edited my answer. — PA.
– PA., Commented Aug 1, 2012 at 15:28
Possible duplicate of check "IF" condition inside FOR loop (batch/cmd) — T.Todua
– T.Todua, Commented Aug 3, 2016 at 9:45

PA. · Accepted Answer · 2012-08-01 15:38:00Z

3

The problem is that your code doesnt apply delayed expansion to the FILE_PREFIX so the value is calculated just once in the loop, at parse time; instead of being refreshed every iteration at runtime.

Just change your line to

ren "%%f" !FILE_PREFIX!!COUNT!.zip

and presto! it should work.

But once you correct it, still your method would fail for numbers above 999.

For a more robust implementation, try this alternative

SET /a count=1
for %%f in (*.zip) do  (
  set fn=0000!count!
  echo REN "%%f" !fn:~-4!%%~xf
  set /a count+=1
)

Inside the loop

the code 0000!count! appends some zeros (4 in this case) to the number; so it will follow the sequence 00001, 00002, ... 00009, 000010, 000011, ...
then !fn:~-4! removes all digits but the last N (4 in this example). So it will follow the desired sequence 0001, 0002, ... 0009, 0010, 0011, ...
and %%~xf extracts the extension (.zip in all the cases of this loop) and appends it to form the final filename. So it will follow the desired sequence 0001.zip, 0002.zip, ... 0009.zip, 0010.zip, 0011.zip, ...

This method will work for any number up to 9999. You can easily extend it to 5 o 6 or even more digits.

edited Aug 1, 2012 at 15:38

answered Aug 1, 2012 at 15:24

PA.

29.5k10 gold badges77 silver badges102 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Andrew Backes Over a year ago

Perfect! Thanks for the help! Could you maybe just explain a little about what the various parts of "!fn:~-4!%%~xf" mean?

Collectives™ on Stack Overflow

Batch File If statement inside For loop

1 Answer 1

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related