How to loop over an Array of Arrays as reference?

Question

The below code works if $a is an Array of Arrays, but I need $a to be an reference to the Array of Arrays.

Question

How do I iterate through $a?

#!/usr/bin/perl

use warnings;
use strict;
use Data::Dumper;

my @AoA = ( ['aaa','hdr','500'],
            ['bbb','jid','424'],
            ['ccc','rde','402'],
            );

my $a = \@AoA;

my $s = "bbb";
my $d = "ddd";

for my $i ( 0 .. $#a ) {
    for my $j ( 0 .. $#{ $a[$i] } ) {
        if ($a[$i][$j] eq $s) {
            $a[$i][$j] = $d;
            last;
        }
    }
}

print Dumper $a;

good question! I was actually wondering about the same thing. — cooldood3490
– cooldood3490, Commented Apr 5, 2013 at 19:44

DVK · Accepted Answer · 2012-08-17 15:24:34Z

18

foreach my $row (@$array_ref) {
    foreach my $cell (@$row) {
        if ($cell eq $s) {
            $cell = $d;
            last;
        }
    }
}

Also, to compute the # of elements in array reference (which as you can see from above code you don't need for your specific code), the easiest approach is:

my $count = scalar(@$array_ref);
my $row_count = scalar(@{ $array_ref->[$i] });
my $last_index = $#$array_ref;

Also, to access the data inside an arrayref of arrayrefs, you simply use the dereference operator on it:

$array_ref->[$i]->[$j]; # The second arrow is optional but I hate omitting it.

In addition, you can create your arrayref of arrayrefs the way you did (take a reference to array of arrays), or right away as a reference:

my $array_ref = [
         [1,2,3]
         ,[4,5,6]
        ];

As a side note, please never use $a and $b as identifyer names - they have special purpose (used in sort blocks for example)

edited Aug 17, 2012 at 15:24

answered Aug 17, 2012 at 15:19

DVK

130k33 gold badges219 silver badges337 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

dan1111 Over a year ago

$#$a also works and gives the last array index, which is what was needed in this case. Ugly? Perhaps, but scalar(@$a) isn't exactly intuitive, either.

DVK Over a year ago

@dan - yeah, I included the $#$ operation for completeness. It's not so much ugly, but less readable and definitely less useful. I very rarely have to do C style loops over index increment in Perl.

dan1111 Over a year ago

I agree that C-Style loops should be avoided but for (0..$#array) {} is often useful.

TLP Over a year ago

+1 for using array refs instead of indexes. IMO indexes should only be used when that particular meta info is required for some other purpose.

dan1111 · Accepted Answer · 2012-08-17 15:23:04Z

4

To dereference in Perl, you have a variety of options. For starters, I suggest you read perlref. Here is the relevant code portion with a minimum of changes, so you can see what needs to be different (however, I agree with others' suggestions to make your code more Perlish).

for my $i ( 0 .. $#$a ) {
    for my $j ( 0 .. $#{ $a->[$i] } ) {
        if ($a->[$i][$j] eq $s) {
            $a->[$i][$j] = $d;
            last;
        }
    }
}

answered Aug 17, 2012 at 15:23

dan1111

6,5662 gold badges20 silver badges29 bronze badges

Comments

TLP · Accepted Answer · 2012-08-17 17:18:53Z

The easiest way to dereference, in my opinion, is to always remember that arrays and hashes can only ever contain scalar values (see perldoc perldata). Which means that your array

my @AoA = ( ['aaa','hdr','500'],
            ['bbb','jid','424'],
            ['ccc','rde','402']);

...contains only three scalar values, which are references to other arrays. You could write it like this:

my $first = [ qw(aaa hdr 500) ];      # using qw() which will quote the args
my $sec   = [ qw(bbb jid 424) ];
my $third = [ qw(ccc rde 402) ];
my @all   = ($first, $sec, $third);   # this array is now identical to @AoA

With this in mind, it is simple to imagine (like DVK suggested in his answer) a loop such as:

for my $aref (@all) {
    # $aref will contain $first, $sec, and $third 
}

And knowing that $aref is an array reference, the dereferencing is simple:

for my $aref (@all) {
    for my $value (@$aref) {
        # do your processing here
    }
}

Also, since the values in a for loop are aliased, any changes to them affects the original array. So if the "processing" in the loop above contains an assignment such as

$value = $foo;

That means that the values in @all are also changed, exactly as if you had written:

$all[0][1] = $foo;

Bill Ruppert · Accepted Answer · 2012-08-17 16:19:59Z

1

I found the use of "last" to be ambiguous, inner or outer, so I made it explicit.

for (@$a) {
    INNER:
    for (@$_) {
        do {$_ = $d; last INNER} if $_ eq $s;
    }
}

answered Aug 17, 2012 at 16:19

Bill Ruppert

9,0567 gold badges30 silver badges44 bronze badges

Comments

David W. · Accepted Answer · 2012-08-17 17:18:34Z

Whenever I deal with arrays of arrays or hashes or hashes or arrays of hashes of arrays, I start to think in terms of Object Oriented programming. Perl OOP isn't all that complex, and it hides a lot of the logical complexity.

Now, in this very simple example, it would be a lot easier just to write it without object orientation, and you already have several good answers (you mainly forgot to dereference your references).

But once you start realizing that you can have more complex structures in Perl than simple hashes, arrays, and scalars, your data structures start getting more complex and more difficult to parse without OOP.

#!/usr/bin/env perl

use strict;
use warnings;
use feature qw(say);

my $a_of_a = array_of_arrays->new;

$a_of_a->push(["aaa", "hdr", "500"]);
$a_of_a->push(["bbb", "jid", "424"]);
$a_of_a->push(["ccc", "rde", "402"]);

foreach my $member ($a_of_a->list) {
    my @array = @{$member};
    foreach my $element (@array) {
        printf "%-5.5s  ", $element;
    }
    print "\n";
}


package array_of_arrays;

sub new {
    my $class = shift;
    my $self = [];

    bless $self, $class;
    return $self;
}

sub push {
    my $self = shift;
    my $item = shift;

    push @{$self}, $item;
    return $self;
}

sub pop {
    my $self = shift;

    if (scalar @{$self}) {
        return pop @{$self};
    }
    else {
        return;
    }
}

sub list {
    my $self = shift;
    return @{$self};
}

cdtits · Accepted Answer · 2012-08-17 15:17:56Z

0

for my $x (@{$a}) {
    for (@{$x}) {
        if ($_ eq $s) {
            $_ = $d;
            last;
        }
    }
}

answered Aug 17, 2012 at 15:17

cdtits

1,1286 silver badges7 bronze badges

Collectives™ on Stack Overflow

How to loop over an Array of Arrays as reference?

6 Answers 6

4 Comments

Comments

Comments

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

4 Comments

Comments

Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related