How to iterate over an array of hashes in an array of hashes

Question

Lots of threads about iterating over an array of hashes, which I do daily. However now I want to iterate over an AoH in and AoH. I'm interested in the array "chapters" because I want to add a hash to each array element of that inner array:

$criteria = [
    {
      'title' => 'Focus on Learning',
      'chapters' => [
                          {
                            'content_id' => '182',
                            'criteria_id' => '1',
                            'title' => 'Focus on Learning',
                          },
                          {
                            'content_id' => '185',
                            'criteria_id' => '1',
                            'title' => 'Teachers Role',
                          },
                          {
                            'content_id' => '184',
                            'criteria_id' => '1',
                            'title' => 'Parents in Class',
                          },
                          {
                            'content_id' => '183',
                            'criteria_id' => '1',
                            'title' => 'Students at Home',
                          }
                        ],
      'tot_chaps' => '4'
    },

This, in theory, is want I want to do.

for my $i ( 0 .. $#$criteria ) {
   for my $j ( 0 .. $#$criteria->[$i]{'chapters'}) {
      print $criteria->[$i]{'chapters'}->[$j]{'title'}."\n";
   }
}

print $criteria->[$i]{'chapters'}->[1]{'title'}."\n"; -> Teachers Role

perreal · Accepted Answer · 2012-09-11 13:28:30Z

6

use warnings;
use strict;

foreach my $criterion (@$criteria) {
  foreach my $chapter (@{$criterion->{chapters}}) {
    print $chapter->{title}, "\n";
  }
}

answered Sep 11, 2012 at 13:28

perreal

98.7k23 gold badges159 silver badges187 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

ruakh · Accepted Answer · 2012-09-11 13:30:06Z

2

I agree with perreal, but to answer your question a bit more narrowly — your code should be fine, except that, to use the $#$arrayref notation when $arrayref is no longer a variable, you use curly brackets {} so that Perl can tell the extent of the reference:

   for my $j ( 0 .. $#{$criteria->[$i]{'chapters'}}) {

(Even when $arrayref is a variable, you can use curly brackets to be explicit:

for my $i ( 0 .. $#{$criteria} ) {

. And the same applies to other ways of dereferencing: @$arrayref or @{$arrayref}, %$hashref or %{$hashref}, and so on.)

answered Sep 11, 2012 at 13:30

ruakh

185k29 gold badges292 silver badges324 bronze badges

1 Comment

ysth Over a year ago

perlmonks.org/?node=References+quick+reference summarizes the rules nicely.

Chas. Owens · Accepted Answer · 2012-09-11 13:36:34Z

2

It is often easier to iterate over data structures like this rather than get the indicies of all of the levels (like your code was doing). This lets you handle each level by itself:

for my $criterion (@$criteria) {
    print "$criterion->{title}\n";
    for my $chapter (@{ $criterion->{chapters} }) {
        print "\t$chapter->{title}\n";
    }
}

As a side note, the tot_chaps key is dangerous if this is not a read-only data structure. It is very easy for it to get out of sync with $criterion->{chapters} and duplicates the information already stored in the array:

my $total_chapters = @{ $criterion->{chapters} };

answered Sep 11, 2012 at 13:36

Chas. Owens

65.1k25 gold badges139 silver badges232 bronze badges

Comments

simbabque · Accepted Answer · 2012-09-11 13:33:46Z

0

If you want to add something, just do it. I'm not sure I understood where you want to add what exactly. If you want another key/value pair for each of the chapters, do it like this:

for my $i ( 0 .. $#$criteria ) {
  for my $j ( 0 .. $#{$criteria->[$i]{'chapters'}}) {
    $criteria->[$i]{'chapters'}->[$j]->{'Teachers Role'} = 'Stuff';
  }
}

Also, there was a little bug in the code: use $#{$criteria->[$i]{'chapters'}} instead of $#$criteria->[$i]{'chapters'} because the $# part only works until the first ->, so it tries to access ->[$i]{'chapters'} out of the value of $#$criteria which is a number and doesn't work.

answered Sep 11, 2012 at 13:33

simbabque

54.4k8 gold badges77 silver badges141 bronze badges

4 Comments

breadwild Over a year ago

Thanks for the "value added" answer on how to add the hash.

simbabque Over a year ago

I'm glad you like it. I wasn't really sure what your question was and it seemed the explanations the others offered weren't really the thing you were looking for.

breadwild Over a year ago

oops, I noticed that while the "add" part worked, it wasn't until I applied the {}'s pointed out by ruakh

simbabque Over a year ago

That was in my answer as well, below the line. ;-)

Collectives™ on Stack Overflow

How to iterate over an array of hashes in an array of hashes

4 Answers 4

Comments

1 Comment

Comments

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

1 Comment

Comments

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related