How to extract the last element of a string and use it to grow an array inside a loop

Question

I have a dataset like this:

10001;02/07/98;TRIO;PI;M^12/12/59^F^^SP^09/12/55

;;;;;M1|F1|SP1;11;10;12;10;12;11;1.82;D16S539

;;;;;M1|F1|SP1;8;8;8;8;10;8;3.45;D7S820

;;;;;M1|F1|SP1;14;12;12;11;14;11;1.57;D13S317

;;;;;M1|F1|SP1;12;12;13;12;13;8;3.27;D5S818

;;;;;M1|F1|SP1;12;12;12;12;12;8;1.51;CSF1PO

;;;;;M1|F1|SP1;8;11;11;11;11;8;1.79;TPOX

;;;;;M1|F1|SP1;6;9;9;6;8;6;1.31;TH01

I'm trying to extract the last element of the lines which does not start with a number, i.e. all lines except the first one. I want to put these values inside an array called @markers.

I'm trying that by the following code:

#!usr/bin/perl
use warnings;
use strict;

open FILE, 'test' || die $!;

while (my $line = <FILE>) {

    my @fields = (split /;/), $line;

    if ($line !~ m/^[0-9]+/) {

    my @markers = splice @fields, 0, @fields - 1;

    }
}

But that does not work. Can anyone help please? Thanks

ikegami · Accepted Answer · 2012-10-08 21:48:02Z

2

You create a new variable named @markers every pass of the loop.
my @fields = (split /;/), $line; means (my @fields = (split /;/, $_)), $line;. You meant my @fields = (split /;/, $line);
'test' || die $! is the same as just 'test'.

use strict;
use warnings;

open my $FILE, '<', 'test'
   or die $!;

my @markers;
while (<$FILE>) {
    chomp;
    next if /^\s*\z/;  # Skip blank lines.
    my @fields = split /;/;
    push @markers, $fields[-1]
        if $fields[0] eq '';
}

answered Oct 8, 2012 at 21:48

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

vitor Over a year ago

Thank you guys very much. Only one last question: how can I use this array to initialize a hash, using the array as keys and all the values = zero?

ikegami Over a year ago

my %hash = map { $_ => 0 } @markers; but you could avoid the array entirely by using $hash{$fields[-1]} = 0; instead of push @markers, $fields[-1];.

Mike · Accepted Answer · 2012-10-08 21:57:26Z

0

You aren't using function split() correctly. I have fixed it in the code below and printed the values:

#!/usr/bin/perl
use warnings;
use strict;

open FILE, 'test' || die $!;

while (my $line = <FILE>) {

    my @fields = split( /;/, $line);

    if ($line !~ m/^[0-9]+/) {

        print "$fields[-1]";
#    my @markers = splice @fields, 0, @fields - 1;

    }
}

answered Oct 8, 2012 at 21:57

Mike

2583 silver badges8 bronze badges

3 Comments

Mike Over a year ago

Above answer is better, I was working on the solution while someone else beat me to the answer.

vitor Over a year ago

Thank you guys very much. Only one last question: how can I use this array to initialize a hash, using the array as keys and all the values = zero?

Mike Over a year ago

You could use a foreach loop to assign the hash key and set value to zero.

Collectives™ on Stack Overflow

How to extract the last element of a string and use it to grow an array inside a loop

2 Answers 2

2 Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related