Does XSLT have a Split() function?

Question

I have a string in a node and I'd like to split the string on '?' and return the last item in the array.

For example, in the block below:

<a>
    <xsl:attribute name="href">
        /newpage.aspx?<xsl:value-of select="someNode"/>
    </xsl:attribute>
    Link text
</a>

I'd like to split the someNode value.

Edit: Here's the VB.Net that I use to load the Xsl for my Asp.Net page:

Dim xslDocPath As String = HttpContext.Current.Server.MapPath("~/App_Data/someXslt.xsl")
Dim myXsltSettings As New XsltSettings()
Dim myXMLResolver As New XmlUrlResolver()

myXsltSettings.EnableScript = True
myXsltSettings.EnableDocumentFunction = True

myXslDoc = New XslCompiledTransform(False)
myXslDoc.Load(xslDocPath, myXsltSettings, myXMLResolver)

Dim myStringBuilder As New StringBuilder()
Dim myXmlWriter As XmlWriter = Nothing

Dim myXmlWriterSettings As New XmlWriterSettings()
myXmlWriterSettings.ConformanceLevel = ConformanceLevel.Auto
myXmlWriterSettings.Indent = True
myXmlWriterSettings.OmitXmlDeclaration = True

myXmlWriter = XmlWriter.Create(myStringBuilder, myXmlWriterSettings)

myXslDoc.Transform(xmlDoc, argumentList, myXmlWriter)

Return myStringBuilder.ToString()

Update: here's an example of splitting XML on a particular node

Does not really have anything to do with ASP.Net

Ikke
– Ikke

2009-11-10 12:34:08 +00:00
Commented Nov 10, 2009 at 12:34 — Ikke
– Ikke, Commented Nov 10, 2009 at 12:34

Alex Angas · Accepted Answer · 2009-11-10 12:32:22Z

51

Use a recursive method:

<xsl:template name="output-tokens">
    <xsl:param name="list" /> 
    <xsl:variable name="newlist" select="concat(normalize-space($list), ' ')" /> 
    <xsl:variable name="first" select="substring-before($newlist, ' ')" /> 
    <xsl:variable name="remaining" select="substring-after($newlist, ' ')" /> 
    <id>
        <xsl:value-of select="$first" /> 
    </id>
    <xsl:if test="$remaining">
        <xsl:call-template name="output-tokens">
            <xsl:with-param name="list" select="$remaining" /> 
        </xsl:call-template>
    </xsl:if>
</xsl:template>

edited Nov 10, 2009 at 12:32

Alex Angas

60.2k41 gold badges145 silver badges213 bronze badges

answered Sep 26, 2008 at 18:04

mortenbpost

1,71716 silver badges22 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

LarsH Over a year ago

Note that if there are no tokens in the list, this template will nevertheless output an empty <id> element, instead of no <id> elements.

monojohnny Over a year ago

I was quite excited about trying this, but Firefox unfortunately says : "Error during XSLT transformation: XSLT Stylesheet (possibly) contains a recursion.". Yes, Firefox it's supposed to be recursive...duh...

Abel · Accepted Answer · 2015-09-13 21:03:50Z

12

If you can use XSLT 2.0 or higher, you can use tokenize(string, separator):

tokenize("XPath is fun", "\s+")
Result: ("XPath", "is", "fun")

See the w3schools XPath function reference.

By default, .NET does not support XSLT 2.0, let alone XSLT 3.0. The only known 2.0+ processors for .NET are Saxon for .NET with IKVM, Exselt, a .NET XSLT 3.0 processor currently in beta, and XMLPrime XSLT 2.0 processor.

edited Sep 13, 2015 at 21:03

Abel

57.5k25 gold badges159 silver badges260 bronze badges

answered Sep 25, 2008 at 22:14

Jacob

23.2k8 gold badges43 silver badges55 bronze badges

3 Comments

Greg Beech Over a year ago

The only down-side is that it requires XSLT 2.0 :-(

travis Over a year ago

yeah, i'm getting a "'tokenize()' is an unknown XSLT function." error

James Sulak Over a year ago

Which processor are you using?

travis · Accepted Answer · 2008-09-25 23:47:08Z

8

I ended up using the substring-after() function. Here's what worked for me:

<a>
    <xsl:attribute name="href">
        /newpage.aspx?<xsl:value-of select="substring-after(someNode, '?')"/>
    </xsl:attribute>
    Link text
</a>

Even after setting the version of my XSLT to 2.0, I still got a "'tokenize()' is an unknown XSLT function." error when trying to use tokenize().

edited Sep 25, 2008 at 23:47

answered Sep 25, 2008 at 23:24

travis

36.6k21 gold badges74 silver badges97 bronze badges

1 Comment

Moe Over a year ago

I wish I had kept the code, but at my previous employer I wrote a xslt 1.0 function to get the n-th token of a string. It's not too difficult once you wrap your head around the concept functional programming

Paul Wagland · Accepted Answer · 2010-05-19 16:06:49Z

6

Adding another possibility, if your template engine supports EXSLT, then you could use tokenize() from that.

For example:

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:str="http://exslt.org/strings"
                extension-element-prefixes="str">

...
  <a>
    <xsl:attribute name="href">
      <xsl:text>/newpage.aspx?</xsl:text>
      <xsl:value-of select="str:tokenize(someNode)[2]"/>
    </xsl:attribute>              
  </a>
...
</xsl:stylesheet>

answered May 19, 2010 at 16:06

Paul Wagland

29.4k10 gold badges55 silver badges75 bronze badges

1 Comment

travis Over a year ago

Have you used this successfully in .net?

James Sulak · Accepted Answer · 2008-09-26 18:44:02Z

3

.NET doesn't support XSLT 2.0, unfortunately. I'm pretty sure that it supports EXSLT, which has a split() function. Microsoft has an older page on its implementation of EXSLT.

answered Sep 26, 2008 at 18:44

James Sulak

32.6k11 gold badges55 silver badges58 bronze badges

Comments

Tasos K. · Accepted Answer · 2014-10-21 10:53:25Z

You can write a template using string-before and string-after functions and use it across. I wrote a blog on this.

Finally came up with a xslt template that would split a delimited string into substrings. I don’t claim it’s the smartest script, but surely solves my problem.

Stylesheet:

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<xsl:for-each select="Paths/Item">
<xsl:call-template name="SplitText">
<xsl:with-param name="inputString" select="Path"/>
<xsl:with-param name="delimiter" select="Delimiter"/>
</xsl:call-template>
<br/>
</xsl:for-each>
</xsl:template>
<xsl:template name="SplitText">
<xsl:param name="inputString"/>
<xsl:param name="delimiter"/>
<xsl:choose>
<xsl:when test="contains($inputString, $delimiter)">
<xsl:value-of select="substring-before($inputString,$delimiter)"/>
<xsl:text disable-output-escaping = "no"> </xsl:text>
<xsl:call-template name="SplitText">
<xsl:with-param name="inputString" select="substring-after($inputString,$delimiter)"/>
<xsl:with-param name="delimiter" select="$delimiter"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="$inputString = ''">
<xsl:text></xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$inputString"/>
<xsl:text> </xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

XML file (to be transformed) :

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="textSpliter.xslt"?>
<Paths>
  <Item>
    <Path>C:\ProgramFiles\SomeWierdSoftware</Path>
    <Delimiter>\</Delimiter>
  </Item>
</Paths>

Greg Beech · Accepted Answer · 2008-09-25 22:18:09Z

1

XSLT 1.0 doesn't have a split function per se, but you could potentially achieve what you're trying to do with the substring-before and substring-after functions.

Alternatively, if you're using a Microsoft XSLT engine, you could use inline C#.

answered Sep 25, 2008 at 22:18

Greg Beech

137k45 gold badges210 silver badges249 bronze badges

Comments

AmbroseChapel · Accepted Answer · 2008-09-26 08:04:59Z

1

Just for the record, if you're doing this with 1.0, and you really need a split/tokenise, you need the xslt extensions.

answered Sep 26, 2008 at 8:04

AmbroseChapel

12.1k7 gold badges50 silver badges69 bronze badges

1 Comment

travis Over a year ago

interesting, how would i use that in the example above?

Collectives™ on Stack Overflow

Does XSLT have a Split() function?

8 Answers 8

2 Comments

3 Comments

1 Comment

1 Comment

Comments

Comments

Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

8 Answers 8

2 Comments

3 Comments

1 Comment

1 Comment

Comments

Comments

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related