How can I create or replace a file using Applescript?

Question

I'm trying to write content to a file, /tmp/test.txt with AppleScript.

If the file doesn't exist, I want to create it.
If it does exist, I want to replace the contents.

This is proving quite difficult because AppleScript has a different syntax for creating a new file versus writing to an existing file. I also thought about deleting a file if it already exists, and then creating it, but AppleScript will move things to the trash by default and so even that is rather complicated.

The data I am going to write to the file may have a lot of special characters in it, so I don't really want to do something like do shell script "cat " + data + " > /tmp/txt.txt" because I am unaware of any escapeshellarg for AppleScript.

Below is what I have so far but I'm getting an error:

Can't make file "Macintosh HD:private:tmp:test.txt" into type reference.

I would really like to abstract this by improving the helper function write_to_file that I got here so that it would take care of creating the file if it does not exist.

my write_to_file("hello", "/tmp/test.txt", false)

on write_to_file(this_data, target_file, append_data)
    try

        if not (exists POSIX file target_file) then
            make new document file at ("/tmp/" as POSIX file as alias) with properties {name:"test.txt", text:the_data}
        end if

        set the target_file to the target_file as POSIX file
        set the open_target_file to open for access file target_file with write permission
        if append_data is false then set eof of the open_target_file to 0
        write this_data to the open_target_file starting at eof
        close access the open_target_file
        return true
    on error e
        try
            display dialog e
            close access file target_file
        end try
        return false
    end try
end write_to_file

How can I create or replace a file using Applescript?

dj bazzie wazzie · Accepted Answer · 2012-12-03 19:56:53Z

The first mistake you've made is mixing POSIX paths with HFS paths. A posix path is /tmp/test.txt and a hfs path to the same file will be Macintosh HD:tmp:test.txt if the name of the boot volume is Macintosh HD of course.

open for access file "Volume:Path:to:file.txt"

The second mistake is that for Mac OS X the /tmp folder is not the place to store temporary files. You will need administrator privileges to write there and the user will be prompted for username and password. It is stored in /var/folders and there is a folder created at login for each user, also with fast user switching. To access the path to this folder you should use the command path to temporary items. Temporary items will be removed between startups.

set theFile to (path to temporary items as string) & "test.txt"

The third mistake is that when you're using quoted form of you can use do shell script. Since AppleScript is unicode like the shell there is no such thing as that characters can't be handled by do shell script.

do shell script "/bin/echo -n " & (quoted form of "$@%^&*()@") & " > " POSIX path of theFile

At last you've made the mistake that you need to check for existence of a file. When you're using open for access command the file will be created when it doesn't exists for you. So the only code you need is:

set theFile to (path to temporary items as text) & "test.txt"
writeToFile(theFile, "Hello!", false)
writeToFile(theFile, (linefeed & "Goodbye!" as string), true)

on writeToFile(p, d, a)
    try
        set fd to open for access file p with write permission
        if not a then set eof of fd to 0
        write d to fd starting at (get eof of fd) as «class utf8»
        close access fd
    on error
        close access file p
    end try
end writeToFile

or using a do shell script which creates an UTF-8 file as well but the given path needs to be an POSIX path now

set theFile to (path to temporary items as text) & "test.txt"
writeToFile(POSIX path of theFile, "goodbye!", false)
writeToFile(POSIX path of theFile, (linefeed & "hello!" as string), true)

on writeToFile(p, d, a)
    set cmd to "/bin/echo -n " & quoted form of d & " >"
    if a then set cmd to cmd & ">"
    do shell script cmd & space & quoted form of p
end writeToFile

Choose the one to your likings

adayzdone · Accepted Answer · 2012-12-03 16:58:09Z

1

Try:

my write_to_file("hello", "/tmp/test.txt", true)

on write_to_file(this_data, target_file, append_data)
    try
        tell application "System Events" to exists file target_file
        if not the result then do shell script "> " & quoted form of target_file
        set the open_target_file to open for access target_file with write permission
        if append_data is false then set eof of the open_target_file to 0
        write this_data to the open_target_file starting at eof
        close access the open_target_file
        return true
    on error e
        try
            display dialog e
            close access target_file
        end try
        return false
    end try
end write_to_file

edited Dec 3, 2012 at 16:58

answered Dec 3, 2012 at 5:20

adayzdone

11.2k3 gold badges23 silver badges37 bronze badges

Collectives™ on Stack Overflow

How can I create or replace a file using Applescript?

How can I create or replace a file using Applescript?

2 Answers 2

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

How can I create or replace a file using Applescript?

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related