Is there a better way to remove a string for an array of strings in perl?

Question

I have a Perl array of URLs that all contain "http://". I'd like to remove that string from each one leaving only the domain. I'm using the following for loop:

#!/usr/bin/perl

### Load a test array
my @test_array = qw (http://example.com http://example.net http://example.org);

### Do the removal
for (my $i=0; $i<=$#test_array; $i++) {
    ($test_array[$i] = $test_array[$i]) =~ s{http://}{};
}

### Show the updates
print join(" ", @test_array);

### Output: 
### example.com example.net example.org

It works fine, but I'm wondering if there is a more efficient way (either in terms of processing or in terms of less typing). Is there a better way to remove a given string from an array of strings?

ikegami · Accepted Answer · 2012-12-05 00:00:10Z

6

When I parse uris, I use URI.

use URI qw( );
my @urls = qw( http://example.com:80/ ... );
my @hosts = map { URI->new($_)->host } @urls;
print "@hosts\n";

answered Dec 5, 2012 at 0:00

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Alan W. Smith Over a year ago

This is great for the specific case I outlined. I was just using that as an example and am really looking for the generic way to deal with strings in arrays. I should have made that clearer in the question.

ErikR · Accepted Answer · 2012-12-04 23:49:54Z

5

You don't need the assignment in this line:

($test_array[$i] = $test_array[$i]) =~ s{http://}{};

you can just use:

$test_array[$i] =~ s{http://}{};

For even less typing, take advantage of the $_ variable:

for (@test_array) {
  s{http://}{};
}

answered Dec 4, 2012 at 23:49

ErikR

52.2k9 gold badges78 silver badges136 bronze badges

1 Comment

Alan W. Smith Over a year ago

Picking this one since it shows how to deal with strings in general. For something that needs the "http://" removal that I was using as my example case, the answer from ikegami is also worth checking out.

HazySmoke · Accepted Answer · 2012-12-04 23:54:51Z

0

I suggest using the map function. It applies an action to every element in an array. You can condense the for-loop into just one line:

map s{http://}{}, @test_array;

Also, as a side note, an easier way of printing the array contents in space-separated format is to simply put the array inside a double-quoted string:

print "@test_array";

answered Dec 4, 2012 at 23:54

HazySmoke

3652 silver badges8 bronze badges

2 Comments

ikegami Over a year ago

Most people cringe at using map as a topicalizer. s{http://}{} for @test_array; is preferred.

Borodin Over a year ago

map is meant to be used as a list operator. It maps one list to another - hence the name. There is no advantage to using it over the ordinary for, which avoids misappropriating the concept of a mapping, and results in clearer code.

Collectives™ on Stack Overflow

Is there a better way to remove a string for an array of strings in perl?

3 Answers 3

1 Comment

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related