Perl parsing Text File with regular expression

Question

I have a file with the following random structures:

USMS 1362224754632|<REQ MSISDN="00966590832186" CONTRACT="580" SUBSCRIPTION="AAA" FORMAT="ascii" TEXT="L2"

or

USMS 1362224754632|<REQ MSISDN="00966590832186" CONTRACT="580" SUBSCRIPTION="BBB" THRESHOLDID="1" FORMAT="ascii" TEXT="L2"

I am trying to parse it with perl to get the values like the following:

1362224754632;00966590832186;580;AAA;L2

Below is the code:

if($Record =~ /USMS (.*?)|<REQ MSISDN="(.*?)" CONTRACT="(.*?)" SUBSCRIPTION="(.*?)" FORMAT="(.*?)" THRESHOLDID="(.*?)" TEXT="(.*?)"/)
{
                              print LOGFILE "$1;$2;$3;$4;$5;$6;$7\n";
}
elsif($Record =~ /USMS (.*?)|<REQ MSISDN="(.*?)" CONTRACT="(.*?)" SUBSCRIPTION="(.*?)" FORMAT="(.*?)" TEXT="(.*?)"/)
{
                              print LOGFILE "$1;$2;$3;$4;$5;$6\n";
}

But I am getting always:

;;;;;

Birei · Accepted Answer · 2013-03-02 21:50:23Z

3

Pipe (|) is a special character in regular expressions. Escape it, like: \| and it will work.

if($Record =~ /USMS (.*?)\|<REQ MSISDN="(.*?)" CONTRACT="(.*?)" SUBSCRIPTION="(.*?)" FORMAT="(.*?)" THRESHOLDID="(.*?)" TEXT="(.*?)"/)

and the same for the else branch.

answered Mar 2, 2013 at 21:50

Birei

36.4k3 gold badges80 silver badges84 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Schwern · Accepted Answer · 2013-03-02 23:31:35Z

3

Instead of using a single regex, I would split the data into its separate sections first, then approach them separately.

my($usms_part, $request) = split / \s* \|<REQ \s* /x, $Record;

my($usms_id) = $usms_part =~ /^USMS (\d+)$/;

my %request;
while( $request =~ /(\w+)="(.*?)"/g ) {
    $request{$1} = $2;
}

Rather than having to hard code all the possible key/value pairs, and their possible orderings, you can parse them generically in one piece of code.

answered Mar 2, 2013 at 23:31

Schwern

167k28 gold badges225 silver badges370 bronze badges

2 Comments

Jim Black Over a year ago

@Schwern - I up'd your answer. If any of keys are changed in the data file, the original regular expressions will fail - this includes: order of keys, spelling of the keys, and the key counts. Far better to have a more open (or general-purpose?) capturing of the key/value pairs, to account for future changes. And storing in an indexed hash, good add. Though I would have used some form of 'record-number' for the first level key: '$request{$rnum}{$1} = $2;'

snoofkin Over a year ago

I would follow that approach as well.

Myforwik · Accepted Answer · 2013-03-02 21:46:52Z

1

Change

(.*?)

to

([a-zA-Z0-9]*)

answered Mar 2, 2013 at 21:46

Myforwik

3,5985 gold badges37 silver badges44 bronze badges

1 Comment

Ilmari Karonen Over a year ago

This would give him 1362224754632;;;;; instead of just ;;;;;, but wouldn't fix the unescaped pipe problem. It's still good advice in general, though.

Borodin · Accepted Answer · 2013-03-03 14:38:06Z

0

It looks like all you want is the fields contained in double-quotes.

That looks like this

use strict;
use warnings;

while (<DATA>) {
  my @values = /"([^"]+)"/g;
  print join(';', @values), "\n";
}

__DATA__
USMS 1362224754632|<REQ MSISDN="00966590832186" CONTRACT="580" SUBSCRIPTION="AAA" FORMAT="ascii" TEXT="L2"
USMS 1362224754632|<REQ MSISDN="00966590832186" CONTRACT="580" SUBSCRIPTION="BBB" THRESHOLDID="1" FORMAT="ascii" TEXT="L2"

output

00966590832186;580;AAA;ascii;L2
00966590832186;580;BBB;1;ascii;L2

answered Mar 3, 2013 at 14:38

Borodin

127k9 gold badges72 silver badges146 bronze badges

Collectives™ on Stack Overflow

Perl parsing Text File with regular expression

4 Answers 4

Comments

2 Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

2 Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related