awk multiple variables for multiple file processing

Question

I'd like to use awk to process multiple files such as
File 1:

1 1.045
2 1.033
3 1.029

File 2:

1 1.078
2 1.080
3 1.090

but I'm interested in storing a specific field from each file and then printing them all out on one line. For example, I'd like the second field of the second line in both files so that the output would be:

1.033 1.080

Can I get awk to store the field in question from each file in a separate variable or in separate fields of an array? I tried:

awk '
BEGIN{}
FNR==2{var1=$2;nextfile}
FNR==2{var2=$2}
END{printf "%6.3f    %6.3f\n", var1,var2}' file1 file2

but this overwrites var1 with the field from the second file and never processes for var2.

Thor · Accepted Answer · 2013-03-07 17:27:45Z

2

In your example the third line is never evaluated, you could solve it like this:

awk '
BEGIN{}
FNR==2 && !var1 {var1=$2;nextfile}
FNR==2{var2=$2}
END{printf "%6.3f    %6.3f\n", var1,var2}' file1 file2

BUT, this approach is hard to generalize, I would rather do it like this:

awk 'FNR==row { printf "%6.3f    ", $col } END { printf "\n" }' row=2 col=2 file1 file2

Output:

1.033     1.080

answered Mar 7, 2013 at 17:27

Thor

47.7k12 gold badges125 silver badges140 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Chris Seymour · Accepted Answer · 2013-03-07 17:56:07Z

2

A different approach:

$ paste file1 file2 | awk 'NR==2{print $2,$4}'
1.033 1.080

answered Mar 7, 2013 at 17:56

Chris Seymour

86.4k32 gold badges166 silver badges209 bronze badges

Comments

Kent · Accepted Answer · 2013-03-07 16:55:49Z

0

do you want this?

awk 'NR==FNR{a[$1]=$2;next}$1 in a{print a[$1],$2}' file1 file2

outputs:

1.045 1.078
1.033 1.080
1.029 1.090

answered Mar 7, 2013 at 16:55

Kent

197k36 gold badges248 silver badges317 bronze badges

1 Comment

Chris Seymour Over a year ago

He just wants field 2 of line 2 in each file @Kent

Scrutinizer · Accepted Answer · 2013-03-07 20:43:42Z

0

Another approach to try:

awk '{p=$2; getline<f} NR==2{print p,$2; exit}' f=file2 file1

answered Mar 7, 2013 at 20:43

Scrutinizer

9,9661 gold badge24 silver badges23 bronze badges

Collectives™ on Stack Overflow

awk multiple variables for multiple file processing

4 Answers 4

Comments

Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related