Directly access value based on another value in anonymous array of hashes

Question

Given the following anonymous array of hashes:

$AoH = [
    {    
         'FORM_FIELD_ID'        => '10353',
         'VISIBLE_BY'           => '10354',
         'FIELD_LABEL'          => 'ISINCIDENT',
         'VALUE'                => '',
         'DEFAULT_FIELD_LABEL'  => 'Yes No',
         'FORM_ID'              => '2113',
    },
    {
         'FORM_FIELD_ID'        => '10354',
         'VISIBLE_BY'           => '0',
         'FIELD_LABEL'          => 'CATEGORY',
         'VALUE'                => 'zOS Logical Security (RACF)',
         'DEFAULT_FIELD_LABEL'  => 'CATEGORY',
         'FORM_ID'              => '2113',
    },
    {
         'FORM_FIELD_ID'        => '10368',
         'VISIBLE_BY'           => '10354',
         'FIELD_LABEL'          => 'STARTDATE',
         'VALUE'                => '',
         'DEFAULT_FIELD_LABEL'  => 'REQTYPE',
         'FORM_ID'              => '2113',

    }
];

How would I directly access the FIELD_LABEL value given that I knew the FORM_FIELD_ID is 10353?

I know I can loop through @$AoH and conditionally find $_->{FIELD_LABEL} based on $_->{FORM_FIELD_ID} == 10353, but is there anyway to directly access the wanted value if one of the other values in the same hash is known?

If you want direct lookup, you need to remap your FORM_FIELD_ID to a hash key instead. — TLP
– TLP, Commented Jul 8, 2013 at 19:10
Oh my! Satori like insight ... in the Devel::REPL, using dd @$AoH then remapping with my %by_form_field_id = map { $_->{FORM_FIELD_ID} => $_ } @$AoH; then dd %by_form_field_id visually demonstrates where the speed would come from. +1 TLP and amon. — G. Cito
– G. Cito, Commented Jul 8, 2013 at 20:37
A good basic and helpful question. TLP's comment and @amon's answer make it useful for learning about making simple things faster. (Changed tag) — G. Cito
– G. Cito, Commented Mar 9, 2015 at 20:13

amon · Accepted Answer · 2013-07-08 19:12:07Z

4

No, not unless you change your data structure. You could e.g. index the records by their form field id:

my %by_form_field_id = map { $_->{FORM_FIELD_ID} => $_ } @$AoH;

Then:

my $field_label = $by_form_field_id{10353}{FIELD_LABEL};

Without changing the data structure, you really have to grep:

my $field_label = (grep { $_->{FORM_FIELD_ID} == 10353 } @$AoH)[0]->{FIELD_LABEL};

answered Jul 8, 2013 at 19:12

amon

57.8k2 gold badges93 silver badges152 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

G. Cito Over a year ago

if your @AoH is more than trivial in size indexing the array from a hash element like this would be best. +1 for amon who makes it look easy. @amon ... you are making a %HoH's so the "->" is optional and by_form_field_id{10353}{FIELD_LABEL} looks really clean and simple. Is it more perlish to use this data structure approach or would writing a custom search function to use grep count as acceptable in TIMTOWTDI sense?

amon Over a year ago

@G.Cito Creating the lookup hash is an O(n) operation, as is grepping. If I have to perform multiple lookups, I'd create the hash, as each lookup runs in O(1). I.e. for m lookups (m > 1), using a hash is m times as fast as grep. For a single lookup, grep is faster. I don't care about Tim Toady, as long as the right tool for the job is used.

G. Cito Over a year ago

amon, Thanks for that response. I still think I'm operating on the script and small tools side of the perl universe since the grep "shellism" (admittedly a perl function of course) is what first occurred to me. I haven't quite reached the stage where I naturally grok modifying data structures to be computationally efficient. I enjoy posts that help me on this path. Cheers

G. Cito · Accepted Answer · 2013-07-08 19:41:35Z

0

You'd have to write a function loop through @array and examine the %hash or maybe use the builtin grep method:

say $_->{FIELD_LABEL} for (grep { $_->{FORM_FIELD_ID} == 10353 } @$AoH )

works. And so does this:

say %$_->{FIELD_LABEL} for (grep { $_->{FORM_FIELD_ID} == 10353 } @$AoH )

but it gives a Using a hash as a reference is deprecated warning (with pumpkin perl-5.16.3).

answered Jul 8, 2013 at 19:41

G. Cito

6,4063 gold badges31 silver badges42 bronze badges

Collectives™ on Stack Overflow

Directly access value based on another value in anonymous array of hashes

2 Answers 2

3 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related