Plotting only the common data in a data series with GNUPlot

Question

I'm trying to create a graph which shows two lines from two different data sources – which are time-series. My problem is that one source has data for every day, and the other one has sporadic data (and starts later). Like the following image:

enter image description here

I use the following code:

set autoscale xfixmax
set autoscale xfixmin
set xdata time
set timefmt "%s"
set format x "%m/%y"
set y2tics

set terminal png size 1000,500

set datafile sep ','

plot 'a.csv' using 1:2 with line lw 1.2 title 'a' axes x1y1, \
 'b.csv'  using 2:5 with steps lw 2 title 'b' axes x1y2

I'd like just to plot the period where they both have data. Is that possible to do with GNUPlot?

Thanks :)

Christoph · Accepted Answer · 2013-07-31 18:19:55Z

3

You can use the stats command to determine the xrange of both data files. This does not work in timedata mode, but since you have the time given as timestamp you can do this before setting to timedata mode:

set datafile sep ','

stats 'a.csv' using 1:2 prefix 'a'
stats 'b.csv' using 2:5 prefix 'b'

xmin = (a_min_x < b_min_x ? b_min_x : a_min_x)
xmax = (a_max_x < b_max_x ? a_max_x : b_max_x)

set xdata time
set timefmt "%s"
set format x "%m/%y"
set y2tics
set xrange[xmin:xmax]

set terminal png size 1000,500

plot 'a.csv' using 1:2 with line lw 1.2 title 'a' axes x1y1, \
'b.csv'  using 2:5 with steps lw 2 title 'b' axes x1y2

answered Jul 31, 2013 at 18:19

Christoph

48.7k8 gold badges94 silver badges198 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

gaoithe Over a year ago

I had a gnuplot whitespace-field-seperated file with date/time in first field in quotes. I did not find a way to use this file with gnuplot stats command. Needed to set timefmt '"..."' to tell gnuplot first field had quotes around it. Rewriting the file as csv allowed me to use the stats command. '''set datafile sep whitespace''' put the datafile settings back so that I could plot using the whitespace-field-seperated file.

Collectives™ on Stack Overflow

Plotting only the common data in a data series with GNUPlot

1 Answer 1

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related