redirecting stdin/stdout from exec'ed process to pipe in Perl

Question

I am trying to have STDOUT/STDERR from a exec'ed child process go back to the parent via a pipe in Perl. The closest I have seen to what I want to do is at : http://forums.devshed.com/perl-programming-6/exec-and-redirecting-stdout-stderr-168501.html

The following is a stripped down example of what I am trying to do. I also tried a variant of the link above. I can't see what I'm doing wrong...

#!/usr/bin/env perl

use strict ;
use warnings ;

my $cmd    = "/usr/bin/who -a" ;  # anything to stdout

pipe( READER, WRITER ) ;
my $child = fork() ;
if ( $child ) {
    print "I am the parent: My pid = $$ junior = $child\n" ;
    close( WRITER ) ;
    my @output = <READER> ;
    print @output ;
    print "parent is DONE\n" ;
} else {
    print "I am the child. My pid = $$\n" ;

    close( READER ) ;
    close( STDOUT );
    close( STDERR );
    *STDOUT = *WRITER ;
    *STDERR = *WRITER ;

    print WRITER "XXX ouput before exec....\n" ;

    exec( $cmd ) or exit(1) ;
}

You may be interested in IPC::Open2.

squiguy
– squiguy

2013-08-18 03:35:38 +00:00
Commented Aug 18, 2013 at 3:35 — squiguy
– squiguy, Commented Aug 18, 2013 at 3:35

Slaven Rezic · Accepted Answer · 2013-08-18 09:59:22Z

8

It's not possible to redirect file descriptors just with assignments. Rather one needs to use open like described in perldoc -f open. In your case the child code would look like this:

    print "I am the child. My pid = $$\n" ;

    close( READER ) ;

    open STDOUT, ">&", \*WRITER or die $!;
    open STDERR, ">&", \*WRITER or die $!;

    print WRITER "XXX ouput before exec....\n" ;

    exec( $cmd ) or exit(1) ;

answered Aug 18, 2013 at 9:59

Slaven Rezic

4,58116 silver badges12 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

user2404501 · Accepted Answer · 2013-08-18 13:45:53Z

Slaven Rezic has the right answer to why your code doesn't work, but you should also be aware of a shortcut that you can use. The special pipe+fork open READER, '-|' does almost all the setup work for you, creating a child process with its STDOUT writing into a pipe that the parent can read with READER. That just leaves the STDERR redirection for you to do manually.

The shortened version of the code looks like this:

my $child = open READER, '-|';
defined $child or die "pipe/fork: $!\n";
if ( $child ) {
    print "I am the parent: My pid = $$ junior = $child\n" ;
    my @output = <READER> ;
    print @output ;
    print "parent is DONE\n" ;
} else {
    print "I am the child. My pid = $$\n" ;

    open STDERR, '>&STDOUT';

    print "XXX ouput before exec....\n" ;

    exec( $cmd ) or exit(1) ;
}

Dada · Accepted Answer · 2021-06-21 07:02:48Z

0

This code is another way to pipe the STDOUT and STDERR from the child process.

 #!/usr/bin/env perl
 use strict ;
 use warnings;

 my $cmd    = "/usr/bin/who -a" ;  # anything to stdout

 pipe( READER, WRITER ) ;
 my $child = fork() ;
if ( $child ) {
    print "I am the parent: My pid = $$ junior = $child\n" ;
    close( WRITER ) ;
    my @output = <READER> ;
    print @output ;
    print "parent is DONE\n" ;
} else {
    print "I am the child. My pid = $$\n" ;
    close( READER ) ;
    open(STDERR,">&", WRITER) or die "Cannot duplicate STDERR;
    open(STDOUT,">&", WRITER) or die "cannot duplicate STDOUT";

    print WRITER "XXX ouput before exec....\n" ;

   exec( $cmd ) or exit(1) ;
}

edited Jun 21, 2021 at 7:02

Dada

6,7657 gold badges28 silver badges48 bronze badges

answered Jun 26, 2017 at 15:26

kurian

1892 silver badges10 bronze badges

Collectives™ on Stack Overflow

redirecting stdin/stdout from exec'ed process to pipe in Perl

3 Answers 3

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related