Creating Windows batch file to create folder/ files

Question

I would like to create folders from a prefix of certain file then copy multiple files with a certain string in their file name to that folder. For example:

VI files to a folder called DM0008 with the following files

DM0008d3VI_001.IMI
DM0008d3VI_002.IMI

MI files to a folder called DM0008MI with the following files

DM0008d6MI_002.IMI
DM0008d6MI_003.IMI

I did try this but this created a folder for each individual file:

@echo off
for %%a in (*VI*) do (
  md "%%~na" 2>nul
  move "%%~na.*" "%%~na"
)
for %%a in (*MI*) do (
  md "%%~na" 2>nul
  move "%%~na.*" "%%~na"
)

Ansgar Wiechers · Accepted Answer · 2013-08-20 11:06:10Z

1

Assuming that the first part of the file name (DM####) will always be 6 characters long you could do this:

@echo off

setlocal EnableDelayedExpansion

for %%a in (*VI*) do (
  set "folder=%%~na"
  set "folder=!folder:~0,6!"
  if not exist "!folder!" md "!folder!"
  move "%%~nxa" "!folder!"
)
for %%a in (*MI*) do (
  set "folder=%%~na"
  set "folder=!folder:~0,6!MI"
  if not exist "!folder!" md "!folder!"
  move "%%~nxa" "!folder!"
)

answered Aug 20, 2013 at 11:06

Ansgar Wiechers

202k27 gold badges286 silver badges363 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Endoro · Accepted Answer · 2013-08-20 12:44:25Z

0

@ECHO OFF &SETLOCAL
FOR /f "delims=" %%a IN (file) DO (
    FOR /f "delims=" %%b IN ('echo("%%~na"^|sed -r "/VI/s/(..[0-9]+).*/\1/;/MI/s/(..[0-9]+).*/\1MI/"') DO (
        ECHO MD "%%~b" 2>NUL
        ECHO MOVE "%%~fa" "%%~b"
    )
)

sed for Windows

edited Aug 20, 2013 at 12:44

answered Aug 20, 2013 at 12:32

Endoro

37.7k8 gold badges54 silver badges64 bronze badges

Comments

LS_ᴅᴇᴠ · Accepted Answer · 2013-08-20 15:06:53Z

0

If your only directories to use are DM0008 and DM0008MI and your file patterns are DM0008d3VI_*.IMI and DM0008d6MI_*.IMI then:

@ECHO OFF
IF EXIST DM0008d3VI_*.IMI (
    MD DM0008
    MOVE DM0008d3VI_*.IMI DM0008
)
IF EXIST DM0008d6MI_*.IMI (
    MD DM0008MI
    MOVE DM0008d6MI_*.IMI DM0008MI
)

If this is not your specification, please, make it clearer is your question.

answered Aug 20, 2013 at 15:06

LS_ᴅᴇᴠ

11.2k1 gold badge27 silver badges46 bronze badges

Collectives™ on Stack Overflow

Creating Windows batch file to create folder/ files

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related