Batch File for Xml modification

Question

i have an xml file on which i have to do modification basing on some rules and i want to know can we do that in the batch script. suppose the following is the sample of xml file

> > <conf-article article-type="research" content-type="----"
> > dtd-version="---" open-access="no" xml:lang="en" lifecycle="final">
> > <conf-front>
    <conf-proc-meta>
    <conf-proc-id
> > conf-proc-id-type="conf-acronym">cccc</conf-proc-id>
> > <conf-proc-title-group>

and i want to insert the following lines

<!--Delivery Date: 07/23/2013-->
<!--XML Script: sdfasdfdfs-->
<!--Batch: sdfsdfdssfs-->

before <conf-front> tag.This is an example like that i have some more.so i need some help on this.

Is <conf-front> always the third line? Are lines 1 and 2 always the same or are they dynamic? — foxidrive
– foxidrive, Commented Oct 24, 2013 at 13:24

foxidrive · Accepted Answer · 2013-10-24 14:06:21Z

1

Here is another solution to process a folder full of xml files.

It uses a helper batch file by Aacini called findrepl.bat from - https://www.dropbox.com/s/rfdldmcb6vwi9xc/findrepl.bat

Place findrepl.bat in the same folder as the batch file, and remove the REM to make the .tmp version of the files overwrite the original files, after you test it.

@echo off
for %%a in (*.xml) do (
   echo processing "%%a"
      type "%%a" |findrepl "." /e:"<conf-front>" /o:-1:-1 >"%%a.tmp"
         >>"%%a.tmp" echo ^<!--Delivery Date: 07/23/2013--^>
         >>"%%a.tmp" echo ^<!--XML Script: sdfasdfdfs--^>
         >>"%%a.tmp" echo ^<!--Batch: sdfsdfdssfs--^>
      type "%%a" |findrepl /v "." /e:"<conf-front>" /o:-1:-1 >>"%%a.tmp"
   REM move "%%a.tmp" "%%a"
)
pause

answered Oct 24, 2013 at 14:06

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Magoo · Accepted Answer · 2013-10-28 14:38:20Z

1

@ECHO OFF
SETLOCAL
(
 FOR /f "delims=" %%a IN (q19559569.xml) DO (
  ECHO("%%a"|FIND "<conf-front>" >NUL
  IF NOT ERRORLEVEL 1 (
    ECHO(^<!--Delivery Date: 07/23/2013--^>
    ECHO(^<!--XML Script: sdfasdfdfs--^>
    ECHO(^<!--Batch: sdfsdfdssfs--^>
  )
  ECHO(%%a
 )
)>newfile.xml
GOTO :EOF

where q19559569.xml is your original and newfile.xml is created.

Batch is really not a suitable tool for the task.

I've assumed that by "before" you mean "on the line preceding that on which the nominated tag appears" and not "directly before the tag" - that is, between the leading > > and the tag.

Since the inserted text nominated is clearly artificial, if the real text you require is placed in a file called say insertme.txt then replacing the three ECHO statements with

type insertme.txt

should be more flexible.

@ECHO OFF
SETLOCAL
FOR %%x IN (*.xml) DO (
 FOR /f "delims=" %%a IN ('type "%%x"') DO (
  ECHO("%%a"|FIND "<conf-front>" >NUL
  IF NOT ERRORLEVEL 1 (
    ECHO(^<!--Delivery Date: 07/23/2013--^>
    ECHO(^<!--XML Script: sdfasdfdfs--^>
    ECHO(^<!--Batch: sdfsdfdssfs--^>
  )
  ECHO(%%a
 )
)>"%%~nx.new"
GOTO :EOF

This mod should produce a new file with extension .new from the existing .xml files

edited Oct 28, 2013 at 14:38

answered Oct 24, 2013 at 9:36

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

3 Comments

Mallik Over a year ago

if i want the script itself to run for all xml files in the folder then ? and it should write to the same file and the remaining content should not be removed.

Magoo Over a year ago

Really need to be much more specific. Do you want to run on all .xmls producing a new file corresponding to EACH individual .xml, or one gigantic .xml containing all of the data from your original set, each adjusted? This batch should not change anything other than injecting the three lines before the line(s) containing <conf-front> You could check using FC your.xml newfile.xml

Mallik Over a year ago

no not one gigantic xml file. It should write in the corresponding file nonly

npocmaka · Accepted Answer · 2013-10-24 13:15:55Z

0

    @echo off

    ::get the line before desired tag
    for /f "tokens=1 delims=:" %%L in ('findstr /n "<conf-front>" some.xml') do set /a line=%%L-1

    ::create empty file 
    break>"%temp%\empty"

    ::get first <%line%> lines of the file 
    fc "%temp%\empty" "some.xml" /lb  %line% /t |more +4 | findstr /B /E /V "*****" >temp.xml

    :: add additional content
    echo ^<!--Delivery Date: 07/23/2013--^>  >> temp.xml
    echo ^<!--XML Script: sdfasdfdfs--^>  >> temp.xml
    echo ^<!--Batch: sdfsdfdssfs--^>  >> temp.xml

    ::get last <%line%> lines of the file
    type "some.xml" | more +%line%  >> temp.xml

    ::delete temp empty file
    del /Q /F "%temp%\empty"

This will create temp.xml file and you can check if it fits on your needs and then copy it over your old file.Will set this before last <conf-front> tag so I hope there's only one of this kind.And change some.xml with the name of your xml everywhere in the code.

EDIT ~ do this with all .xml in a folder (will not affect subfolders)

 @echo off

 rem cd /d "c:\some_dir"

::create empty file 
break>"%temp%\empty"

:: iterate trough the xml files
setlocal enableDelayedExpansion
for %%X in (*.xml) do (


    set "line="
    ::get the line before desired tag
    for /f "tokens=1 delims=:" %%L in ('findstr /n "<conf-front>" %%~dpsnxX') do set /a line=%%L-1

    ::only in case the tag is presented
    if defined line (

        ::get first <%line%> lines of the file 
        fc "%temp%\empty" "%%~dpsnxX" /lb  !line! /t |more +4 | findstr /B /E /V "*****" >%temp%\temp.%%~nX.xml

        :: add additional content
        echo ^<^^!--Delivery Date: 07/23/2013--^>  >>"%temp%\temp.%%~nX.xml"
        echo ^<^^!--XML Script: sdfasdfdfs--^>  >>"%temp%\temp.%%~nX.xml"
        echo ^<^^!--Batch: sdfsdfdssfs--^>  >>"%temp%\temp.%%~nX.xml"

        ::get last <%line%> lines of the file
        type "%%~dpsnxX" | more +!line!  >>"%temp%\temp.%%~nX.xml"

    )

)
endlocal

:: replace the file with these in temp folder with new content
for %%X in (*.xml) do (
    move /Y "%temp%\temp.%%~nX.xml" "%%~dpnxX" 2>nul
)

::delete temp empty file
del /Q /F "%temp%\empty"

Just change c:\some_dir with your own path.And back-up your dir..

edited Oct 24, 2013 at 13:15

answered Oct 24, 2013 at 7:43

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

12 Comments

Mallik Over a year ago

I have 100 xml files in one folder with different names so how to run this code to change all the xml files.

npocmaka Over a year ago

Can you check it now?

Mallik Over a year ago

Hi i have tried using your code with the changes u have told to do. But i am getting the following error as Cannot access file F:\Documents and Settings\sys\Desktop\test1\+ The process tried to write to a nonexistent pipe. FC: Invalid Switch

npocmaka Over a year ago

This will happen if you have a file without this tag.I'll edit it again :-)

foxidrive Over a year ago

Just a comment to say that FC is not a reliable tool in text mode.

|

Collectives™ on Stack Overflow

Batch File for Xml modification

3 Answers 3

Comments

3 Comments

12 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

3 Comments

12 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related