My batch script bad counting occurrences of string in a file

Question

@echo off
set /a count = 0
for /f "delims=" %%a in ('dir "%~1" /a:-d /b') do call :next "%%a" "%~2"
echo found %count% occurances of "%~2"
pause
GOTO:EOF
:next
set num=
for /f "delims=" %%b in ('find /c %2 ^< %1') do set num=%%b
set /a count=count+num

My code is wrong count of the text specified in the parameter. What's the problem?

I tried running this, it failed if I didn't match the case of the text, but worked fine otherwise. — Darth Continent
– Darth Continent, Commented Nov 5, 2013 at 16:37
If the specified sequence occurs several times in a row it counts as one. — M. Garbarczyk
– M. Garbarczyk, Commented Nov 5, 2013 at 17:21
find will count the number of lines that match your string, so searching xyyx' for 'x' will count as one, even though the x's aren't in a row. If that's not what you want, you'll need a different tool. — Mark
– Mark, Commented Nov 5, 2013 at 17:24

Aacini · Accepted Answer · 2013-11-06 18:09:10Z

1

As Mark said, find return the number of lines that match in a file, not the number of individual strings in one line. To do so, you need to use another method, for example:

@echo off
setlocal EnableDelayedExpansion
set /a count = 0
for /f "delims=" %%a in ('dir "%~1" /a:-d /b') do (
   for /F "delims=" %%b in ('find %2 ^< "%%a"') do call :next "%%b" "%~2"
)
echo found %count% occurances of "%~2"
pause
GOTO:EOF

:next
set num=0
set "line=%~1"
:nextMatch
   set "line2=!line:*%~2=!"
   if "!line2!" equ "!line!" goto endMatchs
   set /A num+=1
   set "line=!line2!"
if defined line goto nextMatch
:endMatchs
set /a count=count+num

For example:

C:> type 1.txt
An example of text file.
This example line have two "example" words.
End of example.

C:> test 1.txt "example"
found 4 occurances of "example"

edited Nov 6, 2013 at 18:09

answered Nov 5, 2013 at 18:26

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

M. Garbarczyk Over a year ago

I think somewhere there is a mistake, script don't run. my_prog.bat "example" 1.txt

foxidrive Over a year ago

Try my_prog.bat 1.txt "example"

M. Garbarczyk Over a year ago

The same. If I type a string, which does not appear correctly returns 0, but I'll type something exist in file it returns an error that the command syntax is incorrect.

M. Garbarczyk Over a year ago

Awesome. I never thought that a seemingly simple script proves to be quite complicated. Excellent knowledge and skills, thank you.

Mark · Accepted Answer · 2013-11-05 18:31:23Z

1

find will count the number of lines that match your string, so searching 'xyyx' for 'x' will count as one match, even though the x's aren't in a row. If that's not what you want, you'll need a different tool.

answered Nov 5, 2013 at 18:31

Mark

3,7401 gold badge24 silver badges33 bronze badges

Collectives™ on Stack Overflow

My batch script bad counting occurrences of string in a file

2 Answers 2

4 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related