Perl: Hash values change after returning from a subroutine

Question

I'm working with hashes in perl, but don't understand why the hash value changes in the following:

use strict;

sub test
{
    my ($value_ref) = @_;
    my %value = %$value_ref;
    $value{'abc'}{'xyz'} = 1;
}

my %hash;
$hash{'abc'}{'xyz'} = 0;
test (\%hash);
print "$hash{'abc'}{'xyz'}\n";

The above returns 1, why doesn't it return 0 like this it does here?

use strict;

sub test
{
    my ($value_ref) = @_;
    my %value = %$value_ref;
    $value{'abc'} = 1;
}

my %hash;
$hash{'abc'} = 0;
test (\%hash);
print "$hash{'abc'}\n";

I imagine it has to do with how I'm passing in %hash. What am I missing?

Hunter McMillen · Accepted Answer · 2013-11-08 19:04:18Z

7

You are getting incorrect results because when you make your copy of the hash using my %value = %$value_ref; you are only getting the top-level keys. The second level, with the key 'xyz', is the one where value is actually stored so any changes to that reference are carried over. You are performing a shallow copy when you need a deep copy.

Luckily there is a CPAN module for that!

use strict;
use Storable qw(dclone);

sub test
{
    my ($value_ref) = @_;
    my %value = %{ dclone($value_ref) };
    $value{'abc'}{'xyz'} = 1;
}

my %hash;
$hash{'abc'}{'xyz'} = 0;
test (\%hash);
print "$hash{'abc'}{'xyz'}\n"; # prints 0

answered Nov 8, 2013 at 19:04

Hunter McMillen

61.8k25 gold badges124 silver badges176 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

daxim Over a year ago

also: Data::Clone, Clone, Clone::PP, Data::Walk::Clone

urie Over a year ago

How do I make the top-level keys to be reference too?

Tim Peoples · Accepted Answer · 2013-11-08 19:01:34Z

3

This is because the "second level" of your hash (IOW: the value for key 'abc') is itself a hash reference. While you're copying the contents of the hash referenced by $value_ref in your assignment:

my %value = %$value_ref;

...this is only doing a "shallow" copy.

When you modify the value for key 'xyz', you're modifying the same hash that is in the original structure passed to the sub.

answered Nov 8, 2013 at 19:01

Tim Peoples

3542 silver badges9 bronze badges

Collectives™ on Stack Overflow

Perl: Hash values change after returning from a subroutine

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related