Perl - reading through command output file line by line

Perhaps the following will be helpful:

use strict;
use warnings;

my ( $fileName, $fh, $i );

while (<>) {
    if ( !$fileName or $fileName ne $ARGV ) {
        $fileName = $ARGV;
        $i        = 0;
    }

    if ( my ($cmd) = /^([A-Z]{5}\d{2}>.+)/ ) {
        $cmd =~ s/\W+/_/g;
        open $fh, '>', $cmd . '_' . ( sprintf '%05d', ++$i ) . '.txt' or die $!;
    }

    print $fh $_;
}

Command-line usage: >perl script.pl logFile1 [logFile2 .. logFileN]

The [ ] notation indicates optional, multiple files.

The script uses a regex to capture the command/server line, then substitutes 'non-word' characters with an underscore, and this plus a count plus .txt becomes the file name to which that block of command text is written. Thus, using your dataset, the following text files were created containing command content:

APRHY01_lt_all_00001.txt
APRHY01_alt_00002.txt
APRHY01_strt_00003.txt
APRHY02_lt_all_00001.txt
APRHY02_alt_00002.txt
APRHY02_strt_00003.txt

The count was inserted just in case the same command was issued more than once to the same server, as this number insures separate files for each.

You haven't showed us the code you're using to parse the file, so it's hard to say what might be wrong with it :-)

For breaking down multi-line log output like this, a good method is to loop through the file, appending lines to a block of text, until you find the first line of the next block -- then flush the block you've been appending and create a new one, starting with the current line.

my $block = "";
while (<>) {
    if (/[A-Z][A-Z][A-Z][A-Z][A-Z][0-9][0-9]\>/) {
        write_block($block) if $block;
        $block = "";
    }
    $block .= $_;
}
write_block($block);

Your

code:

my $srcFile = "new.log";
my $destFile = "deviations.log";
my @grabbed = {};
my $line = "";
open (my $src, "$srcFile") or die "Could not open the log file $srcFile: $!";
open (my $dest, ">>$destFile") or die "Could not open the destination file $destFile: $!";
while ($line = <$src>)
{ if ($line =~ /[A-Z][A-Z][A-Z][A-Z][A-Z][0-9][0-9]\>/)
  { push @grabbed, "Deviations of the output of command: $line\n";
    while ($line = <$src>)
    {if ($line !~ /[A-Z][A-Z][A-Z][A-Z][A-Z][0-9][0-9]\>/)
     {push @grabbed, $line;
     }
     else
     {last;
} } }}
print $dest "\n@grabbed";
close $dest;
close $src;

when executing last on finding a new command line, goes to the outer while ($line = <$src>), thereby already reading the next line (the first output line of the command) and failing to recognize the start of the command. A simple fix is to omit the reading of a new line by labeling the outer loop and using redo instead of last:

LINE:
while ($line = <$src>)
{ if ($line =~ /[A-Z][A-Z][A-Z][A-Z][A-Z][0-9][0-9]\>/)
  { push @grabbed, "Deviations of the output of command: $line\n";
    while ($line = <$src>)
    { if ($line !~ /[A-Z][A-Z][A-Z][A-Z][A-Z][0-9][0-9]\>/)
      { push @grabbed, $line }
      else
      { redo LINE }
} } }