23

I am writing a batch script that will loop through each line of a text file, (each line containing a filename) check if the file exists and then runs the file and moves it.

Here is my batch script:

REM Loop through each line of input.txt
FOR /F "tokens=1-3 delims=, " %%i IN (./ready/input.txt) DO (
  ECHO.
  ECHO.
  ECHO.
  ECHO Check %%i exists, set error flag if it doesnt
  if not exist .\ready\%%i set errorlevel=2
echo return code is %errorlevel%

  ECHO Run %%i if it exists
  if errorlevel 0 call .\ready\%%i

  ECHO Move %%i to archive if no error occured 
  if errorlevel 0 copy .\ready\%%i .\archive\%mydate%_%mytime%_%%j_%%k_%%i

  ECHO Copy line of text to the new output.txt file if an error occured
  if %errorlevel% NEQ 0 >>output.txt %%i, %%j, %%k
)

Here is the output: enter image description here

I do not understand why the "if errorlevel" is not working as expected... if the file does not exist (as in this example where it does not exist) it should NOT try to run the file, it should NOT copy the file, and it should echo a 2 not a 0

Edit 1: I was reading another SO Post regarding "delayed environment variable expansion" I am not sure if this issue is related

Improve this question
5
  • What happens if you do if not "%errorlevel% == "0"? Also, maybe don't set errorlevel itself: batcheero.blogspot.com/2007/07/never-set-errorlevel.html Commented Jan 2, 2014 at 22:14
  • @zero298 same thing occurs when using %errorlevel% - cant view that blog as my work is blocking it =( also tried removing the set errorlevel did not cause any change Commented Jan 2, 2014 at 22:22
  • One other thing I, why do you have .\file\other why not just file/other Commented Jan 2, 2014 at 22:42
  • @zero298 I am just used to using .\ for going to relative subfolders in folder path - personal preference Commented Jan 2, 2014 at 22:47
  • 2
    set errorlevel=2 <--- never change/set a system variable as it overrides the system variable. Also, when using %variable% within a loop requires the use of delayed expansion and !variable! syntax instead of using %variable%. Commented Jan 3, 2014 at 2:44

8 Answers 8

Reset to default
38

ERRORLEVEL and %ERRORLEVEL% are two different variables. That means your code with echo return code is %errorlevel% and if %errorlevel% NEQ 0 >>output.txt %%i, %%j, %%k is probably wrong.

ERRORLEVEL is builtin and used to fetch the result of the last command. You can use it like:

IF ERRORLEVEL 1 ECHO error level is 1 or more

ERRORLEVEL cannot be set, just like bash does not let you set ?= ...

%ERRORLEVEL% is an environmental variable. If %ERRORLEVEL% is set, then its used in your script when you use %ERRORLEVEL%. If %ERRORLEVEL% is not set AND if command extensions are enabled, then it falls back to ERRORLEVEL. ERRORLEVEL does not update %ERRORLEVEL%.

Raymond Chen has a good blog entry on it: ERRORLEVEL is not %ERRORLEVEL%. Some of the content in this answer was shamelessly lifted from it.

Improve this answer
Sign up to request clarification or add additional context in comments.

4 Comments

Yours is the only answer to explicitly state that ERRORLEVEL cannot be set. That is the key piece if information that I think everyone needs.
ERRORLEVEL is not %ERRORLEVEL% is just a catchy title. It doesn't imply that there can be two different variables called %ERRORLEVEL% and ERRORLEVEL. There is already enough confusion around this, no need to add more. Also, ERRORLEVEL can be set, for both meanings of "set". See other answers here.
Actually, you can set %ERRORLEVEL%. If you want to return 1 as errorlevel at the end of a batch or command file, just write "@COPY SetErrorLevelTo1 dummy". It can be useful for example as part of a Visual Studio Pre- or PostBuild Event to cause stopping the build process.
BTW, re just like bash does not let you set ?= ... -- set isn't used to set variables in bash at all (it mutates either shell settings or the active command-line argument list); perhaps you were thinking csh.
12 
@ECHO OFF
SETLOCAL
DEL output.txt 2>nul
REM Loop through each line of input.txt
FOR /F "tokens=1-3 delims=, " %%i IN (.\ready\input.txt) DO (
  ECHO.
  ECHO.
  ECHO.
  ECHO Check %%i exists, set error flag if it doesnt
  if exist .\ready\%%i (set "errorflag=") ELSE (set errorflag=2)
CALL echo return code is %%errorflag%%

  ECHO Run %%i if it exists
  if NOT DEFINED errorflag (
   call .\ready\%%i
   ECHO Move %%i to archive if no error occured
   if errorlevel 1 (SET errorflag=3) ELSE (ECHO copy .\ready\%%i .\archive\%mydate%_%mytime%_%%j_%%k_%%i)
  )
  ECHO Copy line of text to the new output.txt file if an error occured
  if DEFINED errorflag >>output.txt ECHO %%i, %%j, %%k
)
GOTO :EOF

Here's a rewritten procedure.

Note: output.txt is deleted at the start, else the >> would append to any existing file. 2>nul suppresses error messages if the delete fails (eg. file not exist)

Within a block statement (a parenthesised series of statements), the ENTIRE block is parsed and THEN executed. Any %var% within the block will be replaced by that variable's value AT THE TIME THE BLOCK IS PARSED - before the block is executed.

Hence, IF (something) else (somethingelse) will be executed using the values of %variables% at the time the IF is encountered.

Two common ways to overcome this are 1) to use setlocal enabledelayedexpansion and use !var! in place of %var% to access the chnaged value of var or 2) to call a subroutine to perform further processing using the changed values.

Note therefore the use of CALL ECHO %%var%% which displays the changed value of var. CALL ECHO %%errorlevel%% displays, but sadly then RESETS errorlevel.

IF DEFINED var is true if var is CURRENTLY defined.

ERRORLEVEL is a special varable name. It is set by the system, but if set by the user, the user-assigned value overrides the system value.

IF ERRORLEVEL n is TRUE if errorlevel is n OR GREATER THAN n. IF ERRORLEVEL 0 is therefore always true.

The syntax SET "var=value" (where value may be empty) is used to ensure that any stray spaces at the end of a line are NOT included in the value assigned.

The required commands are merely ECHOed for testing purposes. After you've verified that the commands are correct, change ECHO COPY to COPY to actually copy the files.

I used the following input.txt:

seterr1.bat, J1, K1
seterr5.bat,J2,K2
seterr0.bat,J3 K3
seterr5.bat, J4, K4
notexist.bat, J5, K5

With existing files seterr*.bat which contain

@ECHO OFF
EXIT /b 1

(where the 1 in the last line determines the errorlevel returned)

and received the resultant output:

Check seterr1.bat exists, set error flag if it doesnt
return code is 
Run seterr1.bat if it exists
Move seterr1.bat to archive if no error occured
Copy line of text to the new output.txt file if an error occured

Check seterr5.bat exists, set error flag if it doesnt
return code is 
Run seterr5.bat if it exists
Move seterr5.bat to archive if no error occured
Copy line of text to the new output.txt file if an error occured

Check seterr0.bat exists, set error flag if it doesnt
return code is 
Run seterr0.bat if it exists
Move seterr0.bat to archive if no error occured
copy .\ready\seterr0.bat .\archive\__J3_K3_seterr0.bat
Copy line of text to the new output.txt file if an error occured

Check seterr5.bat exists, set error flag if it doesnt
return code is 
Run seterr5.bat if it exists
Move seterr5.bat to archive if no error occured
Copy line of text to the new output.txt file if an error occured

Check notexist.bat exists, set error flag if it doesnt
return code is 2
Run notexist.bat if it exists
Copy line of text to the new output.txt file if an error occured

Note that the COPY is merely ECHOed as I mentioned earlier.

and output.txt

seterr1.bat, J1, K1
seterr5.bat, J2, K2
seterr5.bat, J4, K4
notexist.bat, J5, K5
Improve this answer

3 Comments

Is there any difference between: if exist output.txt (ECHO Y | DEL output.txt) and DEL output.txt 2>nul ?
In effect, no. The second is easier to type.
@Kairan The difference is the '2>nul` code always tries to delete the file, but hides the output to stderr. Whereas if exist checks for existence first and then only proceeds if the file exists. 99% of the time there is no noticeable difference. However, it's possible that other errors can happen besides the file not existing (like if another process has a lock on the file) -- in both scenarios the file will not be deleted, but in the 2>nul scenario the console will suppress the error message, and in the if exist scenario it won't.
5

There is an easy way to set the %errorlevel% with a trick I learned several years ago:

:: force errorlevel to 1
@(call)
echo %errorlevel%
:: force errorlevel to 0
@(call )
echo %errorlevel%
pause

The space after call is necessary to set the %errorlevel% to 0.

Update: After researching this, I found a reference here.

Improve this answer

Comments

4

Use something like the following subroutine:

:return
   ECHO @exit /b %1 >ret.cmd
   CALL ret.cmd
   GOTO :eof

Then use it like this:

:Attempt
   SETLOCAL
   CALL somethingThatFails
   SET retcode=!errorlevel!
   CALL somethingThatPasses : don't care about the errorlevel here
   CALL :return !retcode!
   ENDLOCAL
   CALL :eof

So, the whole thing would looke something like:

test.cmd...

@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION

CALL :Attempt
IF !errorlevel! NEQ 0 (ECHO Attempt Failed) ELSE (ECHO Attempt succeeded!)
GOTO :eof

:Attempt
   SETLOCAL
   CALL somethingThatFails
   SET retcode=!errorlevel!
   CALL somethingThatPasses : don't care about the errorlevel here
   CALL :return %retcode%
   ENDLOCAL
   CALL :eof

:return
   ECHO @exit /b %1 >return.cmd
   CALL ret.bat
   GOTO :eof

somethingthatfails.cmd...

DIR some command that fails >nul 2>&1

somethingthatpasses.cmd...

DIR >nul 2>&1

The one side effect of this is a file laying around called ret.cmd. I usually use an :end subroutine that does cleanup and would delete it.

Improve this answer

Comments

2

For posterity, when specifically setting it to 0, I like

ver >nul

ver.exe always returns 0.

Improve this answer

1 Comment

As it’s currently written, your answer is unclear. Please edit to add additional details that will help others understand how this addresses the question asked. You can find more information on how to write good answers in the help center.
1

for me, simple use of cmd /c exit 2 worked to set the errorlevel and use it locally in a batch file and even after it ended to ask for the errorlevel outside:

set errorlevel=2
:
cmd /c exit %errorlevel%
:
if errorlevel 3 echo 3
if errorlevel 2 echo 2
if errorlevel 1 echo 1
if errorlevel 1 echo 0

Results

>test.bat
2
1
0
>if errorlevel 2 echo 2
2
Improve this answer

1 Comment

You should read the answer from jww to understand why your solution is worse. You should never set the errorlevel with a SET command
0

This is designed to execute the %%i item only if it exists and follow through with checking for errors and move or log. if the %%i item doesn't exist then it will do nothing.

REM Loop through each line of input.txt
FOR /F "tokens=1-3 delims=, " %%i IN (.\ready\input.txt) DO (
  ECHO.
  ECHO.
  ECHO.
  ECHO Check %%i exists, execute it if it does
  if exist .\ready\%%i (
    call .\ready\%%i
    ECHO Move %%i to archive if no error occured 
    if not errorlevel 1 (
        copy .\ready\%%i .\archive\%mydate%_%mytime%_%%j_%%k_%%i
      ) else (
        ECHO Copy line of text to the new output.txt file if an error occurred
        >>output.txt %%i, %%j, %%k
      )
  )
)
Improve this answer

Comments

0

Most of answers doesn't work on all cases (ie: xp, win9x...)

This line will set ERRORLEVEL to 1, works in DOS or later:

<nul find ""
if errorlevel 1 echo ERRORLEVEL is 1 or more

This line will set ERRORLEVEL to 0, works in DOS or later:

echo a |find "a" >nul
if errorlevel==0 echo No Error
Improve this answer

Comments

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.