Convert Java object methods call results to Clojure map

Question

I'm new to Clojure and have created a simple macro to call certain methods on a Java class and return results into a Clojure map and this all works fine. (Also i'm aware of the bean function however the classes I'm using aren't beans).

My question is in regard to the calling code. Is it better form to pass the Java 'methods' as symbols?

I'm not even sure what type .toString is at the moment (in the calling code)? It all works but not sure its idiomatic Clojure.

(defmacro obj-to-map 
  [obj & body]
  (let [afn (fn [[method kw]]
              `(~kw (~method ~obj)))]
  `(assoc {} ~@(mapcat afn (partition 2 body)))))

(obj-to-map "hello" .length :length .toString :value)  

=>  {:value "hello", :length 5}

Maybe github.com/ngrunwald/gavagai would be helpful as well. — georgek
– georgek, Commented Mar 6, 2014 at 16:20
Yeah saw this project but its probably overkill for what I need. Its also fun to work these things out for yourself sometimes! — tgrrr
– tgrrr, Commented Mar 6, 2014 at 23:58

Alex Miller · Accepted Answer · 2014-03-06 04:46:58Z

2

The .toString etc are symbols in the calling code.

I think it would be better to pass the method name and invoke it using ".".

(defmacro obj-to-map 
  [obj & body]
  (let [afn (fn [[method kw]]
              `(~kw (. ~obj ~method)))]
  `(assoc {} ~@(mapcat afn (partition 2 body)))))

(obj-to-map "hello" length :length toString :value)  

=>  {:value "hello", :length 5}

answered Mar 6, 2014 at 4:46

Alex Miller

70.4k25 gold badges125 silver badges168 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

tgrrr Over a year ago

You're right, that looks a lot nicer. "clojure.org/java_interop#Java Interop-The Dot special form"

diziaq · Accepted Answer · 2022-08-04 11:18:49Z

As an option consider solving this without macros. A macro would still implicitly use reflection, and here it is enough to apply clojure.lang.Reflector/invokeInstanceMethod

The basic implementation is obj-to-map followed by to simple modifications with var-args.

; just a reusable object for calling no-arg methods
(def empty_array (into-array Object []))

; function update-vals available since v1.11.50
(defn obj-to-map [obj methods]
  (update-vals methods
               #(clojure.lang.Reflector/invokeInstanceMethod
                  obj % empty_array)))

(defn obj-to-map2 [obj & methods]
  (obj-to-map obj (apply hash-map methods)))

(defn obj-to-map3 [obj & methods]
  (obj-to-map obj (into {} (for [k methods] [(keyword k) k]))))
    
(defn obj-to-map4 [obj & methods]
  (obj-to-map obj (into {} (for [k methods] [(keyword k) (str k)]))))

; usage

(obj-to-map "hello" {:len "length" :st "toString"})     ; => {:len 5, :st hello}

(obj-to-map2 "hello" :len "length" :st "toString")      ; => {:st hello, :len 5}

(obj-to-map3 "hello" "length" "toString")               ; => {:length 5, :toString hello}

(obj-to-map4 "hello" 'length 'toString)                 ; => {:length 5, :toString hello}

Docs: update-vals

Collectives™ on Stack Overflow

Convert Java object methods call results to Clojure map

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related