How objects are initialized in delphi XE vs XE4

Question

I have a class

type
  TLoadOption = class
  private
    FAutoSearch: Boolean;
  public
    property AutoSearch: Boolean read FAutoSearch write FAutoSearch;
  end;

In one of the functions i am creating the object of the class in stack

procedure MyView.InitializeForm(const aMsg: MyMsg);
//---------------------------------------------------------------------------
var
  Options: TLoadOption;
begin

  if aMsg.OptionalObject <> nil then
   Options := aMsg.OptionalObject as TLoadOption;

  if Assigned(Options) and Options.AutoSearch then
    DoRefresh;
end;

I am not passing anything in aMsg so ideally Options is not set.

In Delphi XE by default Options is set as nil and so this DoRefresh is not called but when i execute the same code in Delpi XE4 the options is initialized with some random value and AutoSearch becomes true always and it results in calling this DoRefresh function which is undesired.

I am wondering if there are any compiler options that set default values to uninitialized variable. My only solution as of now is like this

 procedure MyView.InitializeForm(const aMsg: MyMsg);
    //---------------------------------------------------------------------------
    var
      Options: TLoadOption;
    begin
      Options := nil;

      if aMsg.OptionalObject <> nil then
       Options := aMsg.OptionalObject as TLoadOption;

      if Assigned(Options) and Options.AutoSearch then
        DoRefresh;
    end;

is this a correct way?

What is MyMsg? This is a class, record or what? You say about default value, but this param have no default value in your case. How you assign default value? — Darthman
– Darthman, Commented Mar 7, 2014 at 10:26
Didn't the compiler warn you about that code? It should have told you that Options was uninitialized. Never ignore a compiler warning. — Rob Kennedy
– Rob Kennedy, Commented Mar 7, 2014 at 13:16
You accepted the answer that gave the best solution to your problem, but also did not actually answer the question you asked. You asked about initialization of a local variable. — David Heffernan
– David Heffernan, Commented Mar 10, 2014 at 7:04

Community · Accepted Answer · 2017-05-23 12:33:50Z

11

A local class is not initialized. You need to set it to nil before testing its assignment.

See Are delphi variables initialized with a value by default?.

Only local reference-counted variables are initialized (example: String,dynamic arrays,interface,variants).

If you are targeting mobile platforms, where ARC (automatic reference counting) is introduced, classes are reference counted though. See Automatic Reference Counting in Delphi Mobile Compilers.

edited May 23, 2017 at 12:33

CommunityBot

11 silver badge

answered Mar 7, 2014 at 10:35

LU RD

35k5 gold badges103 silver badges324 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Stefan Glienke · Accepted Answer · 2014-03-07 13:09:06Z

7

As the other answers already said the local variable is not initialized. However what I like to add here is that as is nil safe. That means you don't need to check if aMsg.OptionalObject is assigned. You can just write:

var
  Options: TLoadOption;
begin
  Options := aMsg.OptionalObject as TLoadOption;

  if Assigned(Options) and Options.AutoSearch then
    DoRefresh;
end;

Keep in mind that it will throw an exception if OptionalObject does not inherit from TLoadOption. The code looks as that is always the case. So if you are sure about that you can use a hardcast:

begin
  if Assigned(aMsg.OptionalObject) and TLoadOption(aMsg.OptionalObject).AutoSearch then
    DoRefresh;
end;

edited Mar 7, 2014 at 13:09

answered Mar 7, 2014 at 11:07

Stefan Glienke

21.9k2 gold badges54 silver badges113 bronze badges

Comments

J... · Accepted Answer · 2014-03-07 10:40:10Z

6

No. Assuming that TLoadOption is an object (unmanaged reference type) you have to initialize local variables yourself. There is no option to have them initialized for you. Local variables for reference types (except for managed types like strings, etc) that are uninitialized will always contain whatever garbage data was in that location on the stack. This makes use of Assigned impossible.

You might just simplify your code a bit, but this is about as short as it can get.

var
  Options: TLoadOption;
begin
  if aMsg.OptionalObject <> nil then begin
    Options := aMsg.OptionalObject as TLoadOption;
    if Options.AutoSearch then DoRefresh;
  end;
end;

edited Mar 7, 2014 at 10:40

answered Mar 7, 2014 at 10:32

J...

31.5k7 gold badges71 silver badges148 bronze badges

Comments

David Heffernan · Accepted Answer · 2014-03-07 10:36:04Z

3

Options is a local variable, of a non-managed type. Which means that it is not initialized. It can have any value until you initialize it. If the variable sometimes happens to have the value nil without you having initialized it, then that's just unlucky for you.

You must initialize local variables before attempting to read them.

answered Mar 7, 2014 at 10:36

David Heffernan

616k46 gold badges1.1k silver badges1.5k bronze badges

7 Comments

Jeeva Over a year ago

Thanks for your answer but i am curious on How it always work fine in XE?

J... Over a year ago

@Jeeva He answered that - you were just lucky. The most likely explanation is that the calling function (or some previous function) semi-reliably left something higher up on the stack (where your variable ended up) that made the code work - and now that has somehow changed.

David Heffernan Over a year ago

@Jeeva An uninitialized value can have any value. Including nil.

Stefan Glienke Over a year ago

@Jeeva Are you sure you are building with the exact same options? It might already change if you change some compiler options (optimization, stack frames, etc).

J... Over a year ago

@DavidHeffernan Fair point. Let us be neutral in making value judgements and perhaps say that it worked by chance... making what we will of that outcome ;D

|

kot-da-vinci · Accepted Answer · 2014-03-07 12:19:52Z

1

You don't need local var at all.

procedure MyView.InitializeForm(const aMsg: MyMsg);
begin
  if Assigned(aMsg.OptionalObject)
    and (aMsg.OptionalObject is TLoadOption)
    and (aMsg.OptionalObject as TLoadOption).AutoSearch
  then
    DoRefresh;
end;

answered Mar 7, 2014 at 12:19

kot-da-vinci

1,21418 silver badges31 bronze badges

2 Comments

kot-da-vinci Over a year ago

1. You don't need local var. 2. You don't need to initialize it. 3. If OptionalObject does not inherit from TLoadOption nothing will break. 4. As for me this code is logical.

David Heffernan Over a year ago

The local var is good. It makes the code better. It allows you to avoid repeating yourself over and over as you do.

Collectives™ on Stack Overflow

How objects are initialized in delphi XE vs XE4

5 Answers 5

Comments

Comments

Comments

7 Comments

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

Comments

Comments

7 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related