From grep Perl style regex syntax to actual Perl regex pattern matching

Question

I'm unable to convert Perl regex used in grep to perl syntax

#/bin/bash
string="Last logical block address=936640511 (0x37d3ffff), Number of blocks=936640512"
echo $string | grep -Po '(?<=blocks=)[^$]*'

with perl, I'm unable to succeed

#!/usr/bin/perl
my $string="Last logical block address=936640511 (0x37d3ffff), Number of blocks=936640512";
my ($blocks) = $string =~ m/(?<=blocks=)[^$]*/;
print $blocks;

Please advice if I'm using the correct regex.

ikegami · Accepted Answer · 2014-03-21 18:36:07Z

5

The match operator in list context returns the captured texts if there are any, so all you need to do is add a capture (parens) around the bit you want returned.

my ($blocks) = $string =~ /(?<=blocks=)([^$]*)/;
print "$blocks\n";

The lookbehind is just slowing you down.

my ($blocks) = $string =~ /blocks=([^$]*)/;
print "$blocks\n";

We should check if the match actually succeeded.

if ( my ($blocks) = $string =~ /blocks=([^$]+)/ ) {
    print "$blocks\n";
}

But I'm confused as to why you're matching characters other than the dollar sign. You probably meant to match characters other than the newline.

if ( my ($blocks) = $string =~ /blocks=([^\n]+)/ ) {
    print "$blocks\n";
}

Given that you aren't using /s, that can also be written

if ( my ($blocks) = $string =~ /blocks=(.+)/ ) {
    print "$blocks\n";
}

Personally, I'd use

if ( my ($blocks) = $string =~ /blocks=(\S+)/ ) {
    print "$blocks\n";
}

To get all matches, it's just a question of using /g.

for my $blocks ( $string =~ /blocks=(\S+)/g ) {
    print "$blocks\n";
}

edited Mar 21, 2014 at 18:36

answered Mar 21, 2014 at 17:10

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Tom Iv Over a year ago

Thanks ikegami. But in truth both answers are failing as my $string is a multiline output -

Read Capacity results:    Last logical block address=936640511 (0x37d3ffff), Number of blocks=936640512    Logical block length=512 bytes Hence:    Device size: 479559942144 bytes, 457344 MiB, 479.56 GB

Tom Iv Over a year ago

Thanks ikegami!! I have obtained the required output.

TypeIA · Accepted Answer · 2014-03-21 18:08:44Z

1

The [^$] pattern matches "anything except a literal $", not end-of-string as you intended.

Try this instead:

if ($str =~ m/(?<=blocks=)(.*)$/)
{
    my $blocks = $1;
    print $blocks;
}

You can also print $& which is a special variable (man perlvar) corresponding to the last matched string. Then you don't need to use the () capture or $1.

edited Mar 21, 2014 at 18:08

answered Mar 21, 2014 at 16:55

TypeIA

17.4k1 gold badge41 silver badges58 bronze badges

7 Comments

Tom Iv Over a year ago

Thanks. I now understand the meaning of =~, but I tried the above snippet and I see only a blank. Does this mean match was failure?

ikegami Over a year ago

ug, don't use $&. It slows down every regex match without captures in your program.

sateesh Over a year ago

@dvnrrs, while you are right about the 2nd point (regex) your first point is wrong. OP is doing the match in list context and hence $blocks would contain the matched value. Check the section under 'Matching in list context' in the perldoc perlop page.

TypeIA Over a year ago

@sateesh Thanks; removed that from the answer. @ikegami Regarding $1 vs. $& I'll leave it as-is since I present both options without taking a stance on which is better.

ikegami Over a year ago

Mentioning it at all is taking a stance that it's acceptable, but you should never use $&.

|

Collectives™ on Stack Overflow

From grep Perl style regex syntax to actual Perl regex pattern matching

2 Answers 2

2 Comments

7 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

7 Comments

Your Answer

Sign up or log in

Post as a guest

Related