Unix Command Awk: finding the longest strings in a file

Question

I know this might be an old problem and it has been solved by many people; however, my version requires a little bit of twist.

So I have a file, I'll call it quest. For simiplicity here, it just have 4 entry:

John

Christina

Christine

Tom

Now, I want to use awk to get the longest name in this file and I want it to return both Christina and Christine.

This is what I have so far:

<quest awk '{ if(length>x) {x =length; y=$0} } END {print y}'

And it will just return Christina. I think it can be done with just one line but I am having troubles to come up with a clever way to do it. And I appreciate if you can help! And of course, I prefer a single line.

wrt I prefer a single line - any program can be written in a single line so that's not a useful criteria for a solution. Also, using redirection for your input instead of specifying the file name as an awk arg removes your availability of FILENAME in the script and makes it harder to enhance in future if your requirements change in some ways. — Ed Morton
– Ed Morton, Commented Apr 13, 2014 at 23:48

fedorqui · Accepted Answer · 2014-04-14 07:37:09Z

7

You can maybe use the following:

$ awk '{cur=length($0)} FNR==NR{max=(cur>max?cur:max); next} cur==max' file file
Christina
Christine

It loops through the file twice with the syntax awk '...' file file:

First time to get the maximum value - and store it in the max variable. This is the FNR==NR {} block, that ends with a next to stop processing the current line. More info in Idiomatic awk.
Second time to print those lines whose length is max.

Note the usage of max=(cur>max?cur:max to set the maximum. It is a ternary operator that can be read like this: to set max check if cur>max. If that is true, max=length($0); otherwise, max=max.

edited Apr 14, 2014 at 7:37

answered Apr 13, 2014 at 22:20

fedorqui

293k113 gold badges592 silver badges640 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Victoria J. Over a year ago

Thanks for your help! I do understand the short hand (x?T:F) but I am not sure how you looped through the file twice... Also, can I use <file awk.... instead putting file at the end?

fedorqui Over a year ago

@VictoriaJ. see the updated answer. Quoting the reference, "So, the condition NR == FNR is only true while awk is reading the first file". Regarding your second question, no, you have to use awk '...' file file.

Ed Morton Over a year ago

+1 You could avoid calling length() multiple times with a variable and you need to parenthesize the ternary expression for portability: awk '{cur=length($0)} FNR==NR{max=(cur>max?cur:max); next} cur==max' file file.

fedorqui Over a year ago

@EdMorton thank you very much, your {cur=length($0)} makes many sense and code looks cleaner. And also to parenthesize the ternary.

Ed Morton · Accepted Answer · 2014-04-13 23:43:45Z

7

$ awk '{cur=length($0); recs[cur] = recs[cur] $0 ORS; max=(cur>max?cur:max)} END{printf "%s", recs[max]}' file
Christina
Christine

If your file's huge and the above has a memory issue, then:

$ awk '{cur=length($0)} cur>max{recs=""; max=cur} cur>=max{recs = recs $0 ORS} END{printf "%s", recs}' file
Christina
Christine

edited Apr 13, 2014 at 23:43

answered Apr 13, 2014 at 23:26

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

2 Comments

fejese Over a year ago

This solution is good in case of a smaller input but since it's storing everything it would not suite for piping large amount of data through it I guess

Ed Morton Over a year ago

Yeah, if that really was an issue for the user it'd be trivial to delete recs[] every time max increases or just use a variable instead of an array. I added an alternative for that case.

fejese · Accepted Answer · 2014-04-13 22:35:10Z

2

You can use an array to store the (so far) longest line(s)

awk '{if (length($0)==maxlength) {arr[i++]=$0}; if (length($0)>maxlength) {i=0; maxlength=length($0); split("",arr); arr[i++]=$0}}END{for (i in arr) print a[i];}'

Notes:

maxlength stores the length of the so far longest lines
arr stores the so far longest lines
i stores the count of the lines in the array
split("",arr) initialises arr as an empty array

This way you don't have to read the file twice, so you can use it in a pipeline as well

answered Apr 13, 2014 at 22:35

fejese

4,6284 gold badges32 silver badges37 bronze badges

Comments

Vijay · Accepted Answer · 2014-04-14 07:58:31Z

0

You have know about many awk solutions. I would like to also mention that this can be done in perl as well:

perl -lne '$m<($l=length($_))?$m=$l:0;
           push @{$x{$l}},$_;
           END{print "@{$x{$m}}"} ' your_file

Test

answered Apr 14, 2014 at 7:58

Vijay

67.7k94 gold badges238 silver badges327 bronze badges

Collectives™ on Stack Overflow

Unix Command Awk: finding the longest strings in a file

4 Answers 4

4 Comments

2 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

4 Comments

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related