Combine XML documents with XSLT with grouping

This is rather simple, let's assume you have an XML directors.xml:

<directors>
<director>
    <name>director 1</name>
    <born> 5/12/1992 </born>
    <nationality>Italian</nationality>
    <biography>some info on director</biography>
</director>
<director>
    <name>director 2</name>
    <born>21/2/1980</born>
    <nationality>french</nationality>
    <biography>a bit about me</biography>
</director>
</directors>

and an XML movies.xml:

<movies>
<movie>
    <title>movie1</title>
    <director> director 1 </director>
    <date> 1/2/2010 </date>
    <genre> Action</genre>
</movie>
<movie>
    <title>movie2</title>
    <director>director 1</director>
    <date> 1/2/2010 </date>
    <genre> romance</genre>
</movie>
<movie>
    <title> movie3</title>
    <director> director 2</director>
    <date> 1/2/2010 </date>
    <genre> Action</genre>
</movie>
</movies>

If you transform directors.xml with the following XSL Stylesheet, assuming movies.xml is in the same directory as the Stylesheet, you get your desired Output:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output indent="yes"/>

<xsl:key name="movies-by-genre" match="movie" use="genre"/>

<xsl:template match="directors">
    <directors>
        <xsl:apply-templates select="director"/>
    </directors>
</xsl:template>

<xsl:template match="director">
    <xsl:variable name="name" select="normalize-space(name)"/>
    <xsl:copy>
        <xsl:copy-of select="*"/>
        <xsl:for-each
            select="document('movies.xml')//movie
            [count(. | key('movies-by-genre',genre)[1]) = 1]">
            <xsl:if test="key('movies-by-genre',genre)[normalize-space(director)=$name]">
                <movies genre="{genre}">
                    <xsl:for-each select="key('movies-by-genre',genre)">
                        <xsl:if test="normalize-space(director)=$name">
                            <xsl:apply-templates select="."/>
                        </xsl:if>
                    </xsl:for-each>
                </movies>
            </xsl:if>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

<xsl:template match="movie">
    <movie>
        <xsl:copy-of select="title | date"/>
    </movie>
</xsl:template>

</xsl:stylesheet>

You could also move the filename/path of movies.xml to a parameter and control that from your transformation arguments if you need to be more flexible.