Using scalars in regex search

Question

I wrote this code:

my $id = shift;
my $file = shift;
unless(open (INFO, $file)) { print "cant open file\n"; return 0; }
#this is how i do it - i didn't copy the code directly last time:
while(my $line = <info>)
{
    if($line =~ /d\s+S+\s\Q$id\disk\d+s\d+/g)
    {
        print "yay i found it";
        close(INFO);
        return 1;
    }
}
close(INFO);
return 0;

Example for a line that would be good is:

2:     Apple_HFS 0x123456789ABC   999.9 GB   disk2s2

(as u can see $id is "0x123456789ABC")

My question: it doesn't work - it opens the file and read the lines but the maching isn't good. please tell me what am I missing here? I guess my regex is wrong but I couldn't fix it.

I tried google and (of course) Stack overflow (How to evaluate a word saved in a scalar via regular expression in Perl? , Detect exact string value of scalar in regex matching , Use variable as RegEx pattern) but with no luck. I'm sure I'm missing some basics but this isn't my first regex - just the firs to have a scalar in it.

Thank you

$file is the name of the file. You open it but never actually read anything from it. And your regex doesn't take account of the size field 999.9 GB in each record — Borodin
– Borodin, Commented May 20, 2014 at 11:42
thank you all. my original problem was the regex itself. all of you helped with that. @Borodin 's answer also provided me with a more 'pleasant' solution. his comments also taught me some important things. so I mark his answer as best. — zook2005
– zook2005, Commented May 21, 2014 at 7:25

Borodin · Accepted Answer · 2014-05-21 08:46:29Z

The immediate problem is that $file is the name of the file. You open it but never actually read anything from it.

Here are some further comments on your code

It is common practice, and much tidier, to collect the parameters of a subroutine like this
```
my ($id, $file) = @_
```
This also has the advantage of copying the values, so that the actual parameters in the call are in less danger of being modified
You should use the three-parameter form of open and lexical file handles, like this
```
open my $fh, '<', $file
```
In particular, the file is left open when the subroutine exits in your case because you have chosen a global file handle. Lexical handles are closed implicitly when they go out of scope
You should use the $! built-in variable in the open error message to give information on why it failed
An error is generally indicated by a bare return, which returns undef or an empty list, dependent on context. return 0 in list context results in the list (0) which produces a true value if it is assigned to an array
Unless you really need to be able to access all of a file at once, it is generally best to use a while loop to read and process it line by line
The /g regex match modifier is for finding all occurrences of a pattern in a string. It is unnecessary and wasteful if all you want to do is check whether the pattern appears anywhere in the string

Also your regex has a lot of problems. If I add the /x modifier then I can add spaces to show you better what you have written

/ d \s+ S+ \s \Q$id \d isk \d+ s \d+ /x

which matches

a single d character
one or more space characters
one or more S characters
a single space character
The \Q isn't terminated, so the rest of the string is matched literally. If you had \Q$id\E then the rest of the pattern would match
a single digit
the string isk
one or more digits
a single s character
one or more digits

which doesn't come close to matching the record format that you show. It's important to remember that there is no need for your pattern to matc all of the string, so you may want something like just /\b\Q$id\E\b/ which checks that your ID is somewhere in the string with word boundaries at each end. I Don't see a string like 0x123456789ABC appearing elsewhere and giving a false positive

I think the best solution is to split each record on whitespace and check whether the third field matches the ID passed in

Your subroutine should look like this

sub routine {
  my ($id, $file) = @_;

  open my $fh, '<', $file or do {
    warn "Unable to open '$file' for input: $!";
    return;
  };

  while (my $line = <$fh>) {
    my @fields = split ' ', $line;
    if ($fields[2] eq $id) {
      print "Yay! I found it!\n";
      return 1;
    }
  }

  return;
}

mpapec · Accepted Answer · 2014-05-20 10:11:03Z

1

Instead of

my @lines = split(/\n/, $file);

try

my @lines = <INFO>;

or even better,

unless(open (my $INFO, "<", $file)) { print "cant open file\n"; return 0; }
while (my $line = <$INFO>)
{
  # ..
}

Also you've forgot to end quotation of string ie. \Q$string\E

if($line =~ /d\s+S+\s\Q$id\Edisk\d+s\d+/g)

edited May 20, 2014 at 10:11

answered May 20, 2014 at 10:05

mpapec

50.7k8 gold badges72 silver badges133 bronze badges

Comments

arco444 · Accepted Answer · 2014-05-20 10:13:35Z

0

I think the regex is incorrect. I'm not really sure what you're trying to match so I've had an attempt based on the example:

\d+:.*S\s+\Q$id\E.+disk\d+s\d+

This will match:

d+: a digit followed by a colon

.*S\s+ everything up to the 'S' in 'Apple_HFS' and a space

\Q$id\E the id string you're looking for

.+ everything up to 'disk'

disk\d+s\d+ diskXXXsXXX

Works in this snippet:

$id = "0x123456789ABC";
$line = "2:     Apple_HFS 0x123456789ABC   999.9 GB   disk2s2";

if($line =~ /\d+:.*S\s+\Q$id\E.+disk\d+s\d+/g)
{
        print "yay i found it";
}

answered May 20, 2014 at 10:13

arco444

23k12 gold badges66 silver badges67 bronze badges

Collectives™ on Stack Overflow

Using scalars in regex search

3 Answers 3

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related